P_EBWObjectMaxStatus

@AbapCatalog.sqlViewName: 'PFIEBWOBJMAXSTAT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ControllingObject'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
//@EndUserText.label: 'CO PCC Object Max Status'

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@VDM.private:true

define view P_EBWObjectMaxStatus
  with parameters
    P_ToFiscalYearPeriod      : fins_fyearperiod
  as select from           aufk              as _aufk         
    inner join             afpo              as _afpo         on  _aufk.aufnr = _afpo.aufnr
                                                              and _afpo.posnr = '0001'
    left outer to one join P_EBWObjectStatus as _ObjectStatus on _ObjectStatus.OrderID = _aufk.aufnr
    association [1..1] to I_FiscalYearPeriodForCmpnyCode as _FiscalYearForCC on _aufk.bukrs = _FiscalYearForCC.CompanyCode
    association [1..1] to I_COActivityTypeTotalsByPeriod as _ATT on _aufk.objnr = _ATT.ControllingObject
{
  key _aufk.objnr                  as ControllingObject,
      _aufk.aufnr                  as OrderID,
      _aufk.kokrs                  as ControllingArea,
      _aufk.bukrs                  as CompanyCode,
      _aufk.autyp                  as OrderCategory,
      _afpo.matnr                  as Material,
      _aufk.werks                  as Plant,
      _aufk.auart                  as OrderType,
      _aufk.abgsl                  as ResultsAnalysisKey, //RA Key

      _aufk.kalsm                  as CostingSheet, //Costing Sheet

      @DefaultAggregation: #SUM
      sum(case when _ATT.ControllingValueType = '01'
                then _ATT.CostCtrActivityTypeQty
               else 0 end ) as PlanOutputQuantity,
      @DefaultAggregation: #SUM
      sum(case when _ATT.ControllingValueType = '04'
                then _ATT.CostCtrActivityTypeQty
               else 0 end)  as ActualOutputQuantity,
      _afpo.amein                  as ProductionUnit,
      _aufk.prctr                  as ProfitCenter,
      
      _FiscalYearForCC.FiscalPeriodEndDate as VDM_V_KEY_DATE,
      max(
      case when _ObjectStatus.StatusCode = 'I0012'
            and  _afpo.ltrmi <= _FiscalYearForCC.FiscalPeriodEndDate then  _ObjectStatus.StatusCode //Delivery Date

           when _ObjectStatus.StatusCode = 'I0045'
            and _aufk.idat2  <= _FiscalYearForCC.FiscalPeriodEndDate then  _ObjectStatus.StatusCode //Technical Completion Date

           else 'I0002' end )      as StatusCode

}
where _aufk.eb_post = 'X'
  and _aufk.loekz =  '' //Deletion Flag

  and _aufk.pkosa =  '' //Cost Collector for Production Process

  and _aufk.abgsl <> '' //RA Key

  and _FiscalYearForCC.FiscalYearPeriod = $parameters.P_ToFiscalYearPeriod
group by
  ControllingObject,
  _FiscalYearForCC.FiscalPeriodEndDate,
  _aufk.aufnr,
  _aufk.kokrs,
  _aufk.bukrs,
  _aufk.objnr,
  _aufk.autyp,
  _afpo.matnr,
  _aufk.werks,
  _aufk.auart,
  _aufk.abgsl,
  _aufk.kalsm,
  _afpo.psmng,
  _afpo.wemng,
  _afpo.amein,
  _aufk.prctr