P_EBPAO_VarianceOverview1

@AbapCatalog.sqlViewName: 'PEBPAOVARCOVW1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.private: true
@VDM.viewType: #COMPOSITE
define view P_EBPAO_VarianceOverview1
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod
  as select from I_JournalEntryItem as JournalEntryItem
{
  key Ledger,
  key CompanyCode,
  key case
        when OrderID <> '' then OrderID
        else OriginOrder // V-Price Variance (BSX transaction)

      end                               as OrderID,
  key OrderItem,
  key case SubLedgerAcctLineItemType
        when '09120' then '00000'
        when '09121' then '00000'
        when '09122' then '00000'
        else SubLedgerAcctLineItemType
      end                               as SubLedgerAcctLineItemType,

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8
}
where
       BusinessTransactionCategory  =  'EBVP'
  and  TransactionTypeDetermination <> 'GBB'
  and  FiscalYearPeriod             >= $parameters.P_FromFiscalYearPeriod
  and  FiscalYearPeriod             <= $parameters.P_ToFiscalYearPeriod
  and  Ledger                       = $parameters.P_Ledger
group by
  Ledger,
  CompanyCode,
  OrderID,
  OriginOrder,
  OrderItem,
  SubLedgerAcctLineItemType