P_CustomerSalesAreaValueHelp

DDL: P_CUSTOMERSALESAREAVALUEHELP Type: view BASIC

P_CustomerSalesAreaValueHelp is a Basic CDS View in SAP S/4HANA. It reads from 1 data source (I_CustomerSalesArea) and exposes 13 fields with key fields Customer, SalesOrganization, DistributionChannel, Division. It has 4 associations to related views.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_CustomerSalesArea I_CustomerSalesArea from

Associations (4)

CardinalityTargetAliasCondition
[0..*] I_DistributionChannelText _DistributionChannelText $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
[0..*] I_DivisionText _DivisionText $projection.Division = _DivisionText.Division
[0..*] I_SalesGroupText _SalesGroupText $projection.SalesGroup = _SalesGroupText.SalesGroup
[0..*] I_SalesOrganizationText _SalesOrganizationText $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName PCUSTSALESAREAVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
AccessControl.personalData.blockingIndicator IsBusinessPurposeCompleted view
ClientHandling.algorithm #SESSION_VARIABLE view
Search.searchable true view
VDM.viewType #BASIC view
VDM.private true view
Consumption.ranked true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY Customer Customer
KEY SalesOrganization SalesOrganization
KEY DistributionChannel DistributionChannel
KEY Division Division
CustomerName _Customer CustomerName
SalesOrganizationName
DistributionChannelName
DivisionName
SalesGroup SalesGroup
SalesGroupName
AuthorizationGroup AuthorizationGroup
IsBusinessPurposeCompleted IsBusinessPurposeCompleted
_Customer _Customer 
@AbapCatalog: {
    sqlViewName: 'PCUSTSALESAREAVH',
    compiler.compareFilter: true,
    preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
@ClientHandling.algorithm : #SESSION_VARIABLE
@Search.searchable: true
@VDM.viewType: #BASIC
@VDM.private: true
@Consumption.ranked: true
define view P_CustomerSalesAreaValueHelp
  as select from I_CustomerSalesArea
  association [0..*] to I_DistributionChannelText as _DistributionChannelText on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText            as _DivisionText            on $projection.Division = _DivisionText.Division
  association [0..*] to I_SalesGroupText          as _SalesGroupText          on $projection.SalesGroup = _SalesGroupText.SalesGroup
  association [0..*] to I_SalesOrganizationText   as _SalesOrganizationText   on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
{

      @ObjectModel.text.element: ['CustomerName']
      @Search: {
       defaultSearchElement: true,
       fuzzinessThreshold: 0.8,
       ranking: #HIGH
      }
  key Customer,

      @ObjectModel.text.element: ['SalesOrganizationName']
  key SalesOrganization,

      @ObjectModel.text.element: ['DistributionChannelName']
  key DistributionChannel,

      @ObjectModel.text.element: ['DivisionName']
  key Division,

      @Semantics.text: true
      _Customer.CustomerName,

      @Semantics.text: true
      _SalesOrganizationText[1:Language = $session.system_language].SalesOrganizationName,

      @Semantics.text: true
      _DistributionChannelText[1:Language = $session.system_language].DistributionChannelName,

      @Semantics.text: true
      _DivisionText[1:Language = $session.system_language].DivisionName,

      @ObjectModel.text.element: ['SalesGroupName']
      SalesGroup,
      @Semantics.text: true
      _SalesGroupText[1:Language = $session.system_language].SalesGroupName,

      // These fields are needed for DCL

      @Consumption.hidden: true
      AuthorizationGroup,
      @Consumption.hidden: true
      IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      _Customer
}

Learn More