P_CounterPartyWithSide

@AbapCatalog.sqlViewName: 'PCNTRPRTYWTSD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
define view P_CounterPartyWithSide

  as select from I_ACMCustomerCounterparty
{

      @ObjectModel.text.element: ['CustomerName']
  key Counterparty,
      @Semantics.text:true
      cast(substring(rtrim(replace(concat(ACMCounterpartyLastName, concat(' &@', AdditionalName)), '&@', ''),' '),1,80) as md_customer_name) as 
      CustomerName,
      CounterpartyFullName,
      Side,
      Country,
      ACMCounterpartyLastName as Name1,
      AdditionalName as Name2,
      ACMCounterpartyCity as City,
      PostalCode,
      Region,
      IsBusinessPurposeCompleted,
      AuthorizationGroup
}

union

select from lfa1
{

  key cast(lfa1.lifnr as lifnr preserving type)                                                                   as Counterparty,
      @Semantics.text: true
      cast(substring(rtrim(replace(concat(name1, concat(' &@', name2)), '&@', ''),' '),1,80) as md_supplier_name) as CustomerName,
      ltrim(cast(concat( concat(concat( concat(concat_with_space( anred, name1, 1 ), '/' ), stras ), '/'),
                   concat_with_space(concat_with_space(ort01,regio, 1 ), pstlz,1 ) ) as md_customer_full_name) , ' ' ) as CounterpartyFullName,
      cast( 'M' as wlf_pr_side)                                                                                   as Side,
      land1                                                                                                       as Country,
      name1                                                                                                       as Name1,
      name2                                                                                                       as Name2,
      ort01                                                                                                       as City,
      pstlz                                                                                                       as PostalCode,
      regio                                                                                                       as Region,
      cvp_xblck                                                                                                   as IsBusinessPurposeCompleted,
      begru                                                                                                       as AuthorizationGroup
}
where
  loevm is initial