P_CollectionsContactDraft

@AbapCatalog: { sqlViewName: 'PCOLLSCONTDR',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #NOT_REQUIRED,
                  personalData:       { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #TRANSACTIONAL,
        private: true }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                representativeKey: 'BusinessPartnerPerson' }

define view P_CollectionsContactDraft
  as select from I_CollectionContact

  // VDM Associations

  association [0..1] to I_CollectionsContactDraft as _CollectionsContactDraft on  $projection.RelationshipNumber     = _CollectionsContactDraft.RelationshipNumber
                                                                              and $projection.BusinessPartnerCompany = _CollectionsContactDraft.BusinessPartnerCompany
                                                                              and $projection.BusinessPartnerPerson  = _CollectionsContactDraft.BusinessPartnerPerson
                                                                              and $projection.CollectionSegment      = _CollectionsContactDraft.CollectionSegment

  // Contact Person Function

  association [0..1] to I_ContactPersonFunction   as _ContactPersonFunction   on  $projection.ContactPersonFunction = _ContactPersonFunction.ContactPersonFunction

  // Contact Person Department

  association [0..1] to I_ContactPersondepartment as _ContactPersondepartment on  $projection.ContactPersonDepartment = _ContactPersondepartment.ContactPersonDepartment

  // Business Partner Company

  association [1..1] to I_BusinessPartner         as _BusinessPartnerCompany  on  $projection.BusinessPartnerCompany = _BusinessPartnerCompany.BusinessPartner

  // Business Partneer Person

  association [1..1] to I_BusinessPartner         as _BusinessPartnerPerson   on  $projection.BusinessPartnerPerson = _BusinessPartnerPerson.BusinessPartner

{

          // VDM Fields

  key     RelationshipNumber,
  key     BusinessPartnerCompany,
  key     BusinessPartnerPerson,
  key     CollectionSegment,
  key     _CollectionsContactDraft.DraftUUID as DraftUUID,

          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.FirstName
            else _CollectionsContactDraft.FirstName
          end                                as FirstName,

          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.LastName
            else _CollectionsContactDraft.LastName
          end                                as LastName,

          @Semantics: { telephone: { type: [ #PREF ] } }
          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.PhoneNumber
            else _CollectionsContactDraft.PhoneNumber
          end                                as PhoneNumber,

          @Semantics: { telephone: { type: [ #CELL] } }
          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.MobileNumber
            else _CollectionsContactDraft.MobileNumber
          end                                as MobileNumber,

          @Semantics: { telephone: { type: [ #FAX ] } }
          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.FaxNumber
            else _CollectionsContactDraft.FaxNumber
          end                                as FaxNumber,

          @Semantics: { eMail: { address: true } }
          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.EmailAddress
            else _CollectionsContactDraft.EmailAddress
          end                                as EmailAddress,

          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.ContactPersonFunction
            else _CollectionsContactDraft.ContactPersonFunction
          end                                as ContactPersonFunction,

          case
            when _CollectionsContactDraft.DraftUUID is null
                then I_CollectionContact.ContactPersonDepartment
            else _CollectionsContactDraft.ContactPersonDepartment
          end                                as ContactPersonDepartment,

          cast( case
            when _CollectionsContactDraft.DraftUUID is null
                then 'X'
            else ''
          end as boolean )                   as IsActiveEntity,

          cast( 'X' as boolean )             as HasActiveEntity,

          cast( case
            when _CollectionsContactDraft.DraftUUID is null
                then 0
            else _CollectionsContactDraft.DraftCreationDateTime
          end as sdraft_created_at )         as DraftCreationDateTime,

          cast( case
          when _CollectionsContactDraft.DraftUUID is null
              then 0
          else _CollectionsContactDraft.DraftLastChangedDateTime
          end as sdraft_last_changed_at )    as DraftLastChangedDateTime, 

          // Exposed Associations

          _BPContactToFuncAndDept,
          _BpContactToAddress,
          _BusinessPartnerCompany,
          _BusinessPartnerPerson,
          _CollectionSegment,
          _ContactPersonFunction,
          _ContactPersondepartment

}

union all select from I_CollectionsContactDraft

// Business Partner Company

association [1..1] to I_BusinessPartner as _BusinessPartnerCompany on $projection.BusinessPartnerCompany = _BusinessPartnerCompany.BusinessPartner

// Business Partneer Person

association [1..1] to I_BusinessPartner as _BusinessPartnerPerson  on $projection.BusinessPartnerPerson = _BusinessPartnerPerson.BusinessPartner

{
      // VDM Fields

  key RelationshipNumber,
  key BusinessPartnerCompany,
  key BusinessPartnerPerson,
  key CollectionSegment,
  key DraftUUID,
      FirstName,
      LastName,

      @Semantics: { telephone: { type: [ #PREF ] } }
      PhoneNumber,

      @Semantics: { telephone: { type: [ #CELL] } }
      MobileNumber,

      @Semantics: { telephone: { type: [ #FAX ] } }
      FaxNumber,

      @Semantics: { eMail: { address: true } } 
      EmailAddress,

      ContactPersonFunction,
      ContactPersonDepartment,
      cast( '' as boolean ) as IsActiveEntity,

      HasActiveEntity,
      DraftCreationDateTime,
      DraftLastChangedDateTime,

      // Exposed Associations

      _BPContactToFuncAndDept,
      _BpContactToAddress,
      _BusinessPartnerCompany,
      _BusinessPartnerPerson,
      _CollectionSegment,
      _ContactPersonFunction,
      _ContactPersondepartment

}

where
      HasActiveEntity                             <> 'X'
  and _DraftAdministrativeData.DraftIsCreatedByMe =  'X'