P_CmmdtyPrcFixationExerPurg

@AbapCatalog.sqlViewName: 'PPRCFIXEXERPUR'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.viewType                               : #BASIC
@VDM.private: true
@AbapCatalog.preserveKey: true

@ObjectModel.usageType.sizeCategory         : #L
@ObjectModel.usageType.serviceQuality       : #B
@ObjectModel.usageType.dataClass            : #TRANSACTIONAL

define view P_CmmdtyPrcFixationExerPurg // Basic Exercise - Item

  as select from    cped_termgrpout         as termgrpout
    inner join      P_CPED_TERMINPUT_TBLFCT ( P_SAPClient : $session.client ) 
                                            as terminput   on termgrpout.terminput_guid = terminput.terminput_guid
    inner join      cped_formdoc            as formdoc     on termgrpout.forminput_guid = formdoc.forminput_guid
    inner join      cped_knumvtoguid        as knumvtoguid on knumvtoguid.docitem_guid = formdoc.docitem_guid
    inner join      ekko                    as ekko        on ekko.knumv = knumvtoguid.knumv
    inner join      ekpo                    as ekpo        on  ekpo.ebeln = ekko.ebeln
                                                          and ekpo.ebelp = substring( knumvtoguid.kposn, 2, 5 )
    left outer join cped_termconvout        as termconvout on  termconvout.termconvout_guid = termgrpout.termconvout_guid
                                                          and termconvout.convplace        = '0062'
    left outer join cped_termconvin         as termconvin  on  termconvin.termconvin_guid = termgrpout.termconvin_guid
                                                          and termconvin.convplace       = '0062'
                                                          and termconvin.currfrom        = termconvout.usedcurrfrom
                                                          and termconvin.uomfrom         = termconvout.useduomfrom
                                                          and termconvin.currto          = termconvout.usedcurrto
                                                          and termconvin.uomto           = termconvout.useduomto
{
  key  ekko.ebeln                 as PurchasingDocument,
  key  ekpo.ebelp                 as PurchasingDocumentItem,
  key  formdoc.cond_type          as ConditionType,
  key  termgrpout.extension_group as PricingCndnTermExtensionGroup,
  key  termgrpout.termno          as ConditionTermRateFixation,
       termgrpout.forminput_guid  as PrcgConditionFormulaInputUUID,
       terminput.fixtermrate_df34 as PricingConditionTermFixedRate,
       terminput.fixtermcurr      as PrcgConditionTermFixedRateCrcy, 
       terminput.FIXTERMPRUN      as PrcgConditionTermFixedRateQty,
       terminput.FIXTERMUOM       as PrcgCndnTermFixedRateQtyUnit, 
       termgrpout.extension_usage as ConditionTermExtensionUsage,
       @Semantics.quantity.unitOfMeasure: 'ConditionTermUnit'
       termgrpout.termcommquan    as ConditionTermQuantity,
       @Semantics.unitOfMeasure: true
       termgrpout.termcommuom     as ConditionTermUnit,
       termconvout.usedcurrfrom   as PrcgCndnTermCnvrsnSourceCrcy,
       termconvout.usedcurrto     as PrcgCndnTermCnvrsnTargetCrcy,
       termconvin.fixexchrate     as PrcgCndnTermCnvrsnFxdExchRate
}
where
  termgrpout.extension_usage = 'B'