P_ChmlCompositionOverallStatus

@AbapCatalog.sqlViewName: 'PCCMPSTNALLSTS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

@ObjectModel:
{
  resultSet.sizeCategory: #XS,

  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  }
}

define view P_ChmlCompositionOverallStatus

  as select from P_ChmlCmpstnOverallStsCritlty as OverallStsCritlty

  -- Status Text
  association [0..1] to I_ChmlCmpstnOverallStatus as _StatusText on $projection.ChmlCompositionStatus = _StatusText.ChmlCmpstnOverallStatus

  -- Constants
  association [1..1] to P_ChmlCmplConstants       as _Constants  on _Constants.Constant1 = _Constants.Constant1

{
  key ChmlCmplncInfoUUID,

      ChmlCmpstnTotlStsCriticality as ChmlCompositionStsCriticality,
      case
           when ChmlCmpstnTotlStsCriticality  = 1
           then _Constants[inner].ConstantMissing

           when ChmlCmpstnTotlStsCriticality  = 2
           then _Constants[inner].ConstantInProgress

           when ChmlCmpstnTotlStsCriticality  = 3
           then _Constants[inner].ConstantReleased
         end                       as ChmlCompositionStatus,

      _StatusText
}