P_CABusPartInvcItemSumForDC

DDL: P_CABUSPARTINVCITEMSUMFORDC Type: view_entity COMPOSITE

P_CABusPartInvcItemSumForDC is a Composite CDS View in SAP S/4HANA. It reads from 1 data source (I_CABPInvcItemEnhcdForDspCrcy) and exposes 15 fields with key field CABusPartnerInvoiceUUID.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_CABPInvcItemEnhcdForDspCrcy I_CABPInvcItemEnhcdForDspCrcy from

Parameters (1)

NameTypeDefault
P_DisplayCurrency waers_kk

Annotations (6)

NameValueLevelField
VDM.viewType #COMPOSITE view
VDM.private true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.serviceQuality #C view
AccessControl.authorizationCheck #NOT_REQUIRED view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY CABusPartnerInvoiceUUID CABusPartnerInvoiceUUID
CADocumentContainerRefType CADocumentContainerRefType
CADocumentContainerReference CADocumentContainerReference
CreationDate CreationDate
CreationTime CreationTime
DisplayCurrency DisplayCurrency
CAInvoiceAmountInDisplayCrcy
OpenAmountInDisplayCrcy
CashDiscountAmountInDspCrcy
CAEligibleAmountForCshDiscInDC
CAReleasedAmtInDisplayCurrency
CAClearingAmountInDisplayCrcy
_BusPartnerInvoice _BusPartnerInvoice
_DocCtnRefType _DocCtnRefType
_DisplayCurrency _DisplayCurrency 
@VDM.viewType: #COMPOSITE
@VDM.private: true

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C

@AccessControl.authorizationCheck: #NOT_REQUIRED

define view entity P_CABusPartInvcItemSumForDC
  with parameters
    P_DisplayCurrency : waers_kk

  as select from I_CABPInvcItemEnhcdForDspCrcy
                 (P_DisplayCurrency : $parameters.P_DisplayCurrency)

{
      @ObjectModel.foreignKey.association: '_BusPartnerInvoice'
  key CABusPartnerInvoiceUUID,

      //header data

      @ObjectModel.foreignKey.association: '_DocCtnRefType'
      CADocumentContainerRefType,
      CADocumentContainerReference,
      CreationDate,
      CreationTime,

      @ObjectModel.foreignKey.association: '_DisplayCurrency'
      DisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(AmountInDisplayCurrency)        as CAInvoiceAmountInDisplayCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(OpenAmountInDisplayCrcy)        as OpenAmountInDisplayCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(CashDiscountAmountInDspCrcy)    as CashDiscountAmountInDspCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(CAEligibleAmountForCshDiscInDC) as CAEligibleAmountForCshDiscInDC,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(CAReleasedAmtInDisplayCurrency) as CAReleasedAmtInDisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      sum(CAClearingAmountInDisplayCrcy)  as CAClearingAmountInDisplayCrcy,

      /* Associations */
      _BusPartnerInvoice,
      _DocCtnRefType,
      _DisplayCurrency
}

group by
  CABusPartnerInvoiceUUID,
  CADocumentContainerRefType,
  CADocumentContainerReference,
  CreationDate,
  CreationTime,
  DisplayCurrency

Learn More