P_BillingDocProcFlowCP0

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'PBILLGDOPROCFCP0'
define view P_BillingDocProcFlowCP0 
  as select distinct from P_BillingDocProcFlowC0 as LevelC0  --> Level 0 
    inner join            I_BillingDocumentItem as LevelCM1 --> Level Minus 1 (Check for Preliminary Billing Documents)
    on  LevelC0.LevelC0Document             = LevelCM1.BillingDocument
    and LevelC0.LevelC0DocumentItem         = LevelCM1.BillingDocumentItem
    and LevelC0.LevelM1DocumentCategory     != 'PBD' // exclude manual items     

{
      //Key

  key LevelC0.LevelM1Document,  
  key LevelC0.LevelM1DocumentItem,      
  key LevelC0.LevelM1DocumentCategory,   
  key case 
    when LevelCM1.PrelimBillingDocument is initial
      then LevelC0.LevelC0Document
    else
      LevelCM1.PrelimBillingDocument
    end as LevelC0Document,

  key case 
    when LevelCM1.PrelimBillingDocument is initial
      then LevelC0.LevelC0DocumentItem
    else
      LevelCM1.PrelimBillingDocumentItem
    end as LevelC0DocumentItem,

  key case 
    when LevelCM1.PrelimBillingDocument is initial
      then LevelC0.LevelC0DocumentCategory
    else
      'PBD'
    end as LevelC0DocumentCategory,

      //Billing Document

  key LevelC0.BillingDocument,  
      LevelC0.BillingDocumentType,

      //Organization

      LevelC0.SalesOrganization
}