P_BatchInfo

@AbapCatalog.sqlViewName: 'PBATCHINFO'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MASTER}

define view P_BatchInfo
  as select from P_StockBatchInfo   as stck_btch
    inner join   mch1               as mch1      on  stck_btch.matnr     = mch1.matnr
                                                 and stck_btch.charg_sid = mch1.charg
    inner join   P_MaterialInfo                  on stck_btch.matnr = P_MaterialInfo.Material
    inner join   I_Stockcustomising as StockCust on stck_btch.mandt = StockCust.SAPClient
{

  stck_btch.matnr,
  stck_btch.werks,
  stck_btch.charg_sid,
  stck_btch.berid,
  stck_btch.plaab,
  stck_btch.planr,
  stck_btch.sort1,
  stck_btch.sort2,
  stck_btch.delkz,
  stck_btch.sobkz,
  stck_btch.lifnr,
  stck_btch.kdauf,
  stck_btch.kdpos,
  stck_btch.pspel,
  stck_btch.vrfkz,
  stck_btch.plumi,
  stck_btch.mng01,
  stck_btch.mng01c,
  stck_btch.companycodecurrency,
  mch1.vfdat,
  mch1.verab,
  // Salvage field has to come from customizing table

  case
      when StockCust.SalvageDate = 'FVDT1'
      then mch1.fvdt1
      when StockCust.SalvageDate = 'FVDT2'
      then mch1.fvdt2
      when StockCust.SalvageDate = 'FVDT3'
      then mch1.fvdt3
      when StockCust.SalvageDate = 'FVDT4'
      then mch1.fvdt4
      when StockCust.SalvageDate = 'FVDT5'
      then mch1.fvdt5
      when StockCust.SalvageDate = 'FVDT6'
      then mch1.fvdt6
      end  as SalvageDate

}
where
      verab       > '00000000'
  and SalvageDate > '00000000'