P_BankChainChangeDocumentItem

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Bank Chain Change Document Item'
define view entity P_BankChainChangeDocumentItem
  as select from I_ChangeDocumentItem
    inner join   I_ChangeDocLongTableKey on I_ChangeDocLongTableKey.ChangeDocKeyGuid = I_ChangeDocumentItem.ChangeDocTableKey

  association [0..1] to P_BankChainChangeDocument  as _BankChainChangeDocument  on  $projection.ChangeDocObject      = _BankChainChangeDocument.ChangeDocObject
                                                                                and $projection.ChangeDocObjectClass = _BankChainChangeDocument.ChangeDocObjectClass
                                                                                and $projection.ChangeDocument       = _BankChainChangeDocument.ChangeDocument

  association [0..1] to I_ChangeDocChangeIndT as _ChgDocItemChangeTypeText  on  _ChgDocItemChangeTypeText.Value    = $projection.ChangeDocItemChangeType
                                                                            and _ChgDocItemChangeTypeText.Language = $session.system_language
{
  key I_ChangeDocumentItem.ChangeDocObject,
  key I_ChangeDocumentItem.ChangeDocObjectClass,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.DatabaseTable,
  key I_ChangeDocumentItem.ChangeDocTableKey,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key cast ( I_ChangeDocumentItem.ChangeDocItemChangeType  as fap_change_document_type preserving type )      as ChangeDocItemChangeType,

      _ChgDocItemChangeTypeText.Text,
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      I_ChangeDocumentItem.ChangeDocNewUnit,
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,
      I_ChangeDocumentItem.ChangeDocNewCurrency,

      cast ( I_ChangeDocumentItem.ChangeDocPreviousFieldValue as fap_cc_old_fieldval preserving type )        as ChangeDocPreviousFieldValue,
      cast ( I_ChangeDocumentItem.ChangeDocNewFieldValue as fap_cc_new_fieldval preserving type )             as ChangeDocNewFieldValue,

      // Records with ChangeDocDatabaseTableField = KEY must be change to CHAINNO => for right display of a text which is used in UI

      case I_ChangeDocumentItem.ChangeDocDatabaseTableField
               when 'KEY'
                 then  'CHAINNO'
                 else cast ( I_ChangeDocumentItem.ChangeDocDatabaseTableField as fieldname preserving type )
               end                                                                                            as DatabaseTableFieldName,

      cast( 'ITBCHAIN' as tabelle )                                                                           as ObjectDatabaseTable,

      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 4, 3)  as fap_banksrec )                as BkChnCountryKeyOfRecipientBank,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 7, 15) as fap_bankkrec )                as BkChnBankKeyOfRecipientBank,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 22, 35)as fap_banknrec )                as BkChnAcctNumberAtRecipientBank,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 57, 5) as fap_waers )                   as BkChnCurrencyKey,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 62, 3) as fap_bankssnd )                as BkChnCountryKeyOfSenderBank,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 65, 15)as fap_bankksnd )                as BkChnBankKeyOfSenderBank,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 80, 2) as fap_uzawe )                   as BkChnPaymentMethodSupplement,
      cast ( substring(I_ChangeDocLongTableKey.ChangeDocLongTableKey, 83, 2) as fap_chainno )                 as BkChnIntermediaryBank,

      _BankChainChangeDocument,
      _ChgDocItemChangeTypeText
}
where
  I_ChangeDocumentItem.ChangeDocObjectClass = 'BCHAINP'