P_AssetClassText

@AbapCatalog: { sqlViewName: 'PFIASSETCLASST', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #BASIC
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_AssetClassText
  as select from ankt
    inner join   P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = ''
{
  key anlkl                            as AssetClass,
  key spras                            as Language,

      txk20                            as AssetClassName,
      txk50                            as AssetClassDescription,
      cast('CLASSIC' as faa_authcntxt) as AssetAuthorizationContext
}

union all select from faac_acls0_t
  inner join          P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = 'X'
{
  key asset_class                  as AssetClass,
  key language                     as Language,

      description_short            as AssetClassName,
      description_long             as AssetClassDescription,
      cast('NEW' as faa_authcntxt) as AssetAuthorizationContext
}