P_ARProcessFlowQuotation

@AbapCatalog.sqlViewName: 'PARPROCFLOWQUOT'
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_UserContactCard'] 
@EndUserText.label: 'AR Process Flow - Quotation'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.preserveKey:true
define view P_ARProcessFlowQuotation
  as
  
select from I_SalesDocument
  left outer to one join I_SDDocumentPartner as _Partner on  SalesDocument = _Partner.SDDocument  
                                                         and _Partner.PartnerFunction = 'WE'

  association [1..1] to I_UserContactCard as _UserContactCard 
                                              on  _UserContactCard.ContactCardID = $projection.CreatedByUser
  association [0..1] to I_Customer        as _ShipToParty     
                                             on  $projection.ShipToParty = _ShipToParty.Customer

{
  key SalesDocument as QuotationDocument,
      
      SalesDocumentDate,
      
      SalesDocumentType,
      _SalesDocumentType._Text[1:Language = $session.system_language].SalesDocumentTypeName,
      
      OverallSDProcessStatus,
      _OverallSDProcessStatus._Text[1:Language = $session.system_language].OverallSDProcessStatusDesc,
      
      TotalNetAmount,
      
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'       
      TransactionCurrency,
      
      SoldToParty,
      _SoldToParty.CustomerName,
      _SoldToParty.CustomerFullName,
      _Partner.Customer                                       as ShipToParty,
      _ShipToParty.CustomerName                               as ShipToPartyName, 
       
      PurchaseOrderByCustomer,
      
      SalesOrganization,
      _SalesOrganization._Text[1:Language = $session.system_language].SalesOrganizationName,
      DistributionChannel,
      _DistributionChannel._Text[1:Language = $session.system_language].DistributionChannelName,
      OrganizationDivision,
      _OrganizationDivision._Text[1:Language = $session.system_language].DivisionName,
      cast( 
        concat(
        concat( 
        concat(
        concat(
        SalesOrganization, 
        '/'), 
         DistributionChannel), 
         '/'), 
         OrganizationDivision)        as far_salesarea_key ) as SalesAreaSemanticKey,
         
      cast( 
        concat_with_space(
        concat(
        concat_with_space(
        concat(
        _SalesOrganization._Text[1:Language = $session.system_language].SalesOrganizationName, 
        ','), 
        cast(_DistributionChannel._Text[1:Language = $session.system_language].DistributionChannelName as vtxtk), 1), 
        ','),  
        _OrganizationDivision._Text[1:Language = $session.system_language].DivisionName, 1) as txt_vtrber ) 
        as SalesAreaDesc,
         
      
      CustomerPaymentTerms,
      _CustomerPaymentTerms._Text[1:Language = $session.system_language].CustomerPaymentTermsName,
      
      I_SalesDocument.CreatedByUser,
      _UserContactCard.FullName,
      I_SalesDocument.CreationDate,
      CreationTime,
      
      SalesOffice,
      SalesGroup,
      CustomerPurchaseOrderDate,
            
      _Item,
      _ShipToParty,
      _SoldToParty,
      _TransactionCurrency,
      _UserContactCard

}
where
  OvrlItmGeneralIncompletionSts <> ''  and
  SDDocumentCategory = 'B' //Quotation