P_ACTVENTPROJACTCOSTSFORLEDGER

@AbapCatalog.sqlViewName: 'PACTENTPROJLED'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_ACTVENTPROJACTCOSTSFORLEDGER
  as select from P_ActvPROJECTSWITHPROJCAT6 as Project
    inner join   I_GLAccountLineItemRawData as ProjCstLineItm on ProjCstLineItm.ProjectInternalID = Project.ProjectInternalID
                                                             and ProjCstLineItm.Project = Project.Project
    inner join   I_LedgerSourceLedger       as SourceLedger   on ProjCstLineItm.SourceLedger = SourceLedger.SourceLedger
    inner join   P_IsLeadingLedger          as Ledger         on SourceLedger.Ledger = Ledger.Ledger
{
  key ProjCstLineItm.FiscalYear,
  key ProjCstLineItm.LedgerFiscalYear, //key

  key ProjCstLineItm.FiscalPeriod,
  key ProjCstLineItm.FiscalYearPeriod,
  key ProjCstLineItm.PostingDate,
      ProjCstLineItm.AccountingDocument,
      ProjCstLineItm.LedgerGLLineItem,
      ProjCstLineItm.GLAccount,
      ProjCstLineItm.ChartOfAccounts,
      Project.CompanyCode, //key

      Project.ProfitCenter, //key

      Project.ControllingArea,
      Project.ProjectUUID,
      ProjCstLineItm.ProjectInternalID,
      Project.ProjectType,
      Project.ProjectExternalID as Project,
      @Semantics.currencyCode: true
      Project.ProjectCurrency                                    as ControllingObjectCurrency,
      @Semantics.currencyCode: true
      ProjCstLineItm.GlobalCurrency,
      Project.ProjectDescription,
      Project.AvailabilityControlProfile,
      Project.AvailabilityControlIsActive,
      Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
      Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
      cast( cast( 'ACT01' as abap.char( 10  )) as fcom_category) as PlanningCategory,
      Project.ProjectSummaryTaskUUID,
      ProjCstLineItm.CreationDate,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'ControllingObjectCurrency'
      sum(ProjCstLineItm.AmountInObjectCurrency)                 as AmountInObjectCurrency,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      sum(ProjCstLineItm.AmountInGlobalCurrency)                 as AmountInGlobalCurrency


}

where
      ProjCstLineItm.CompanyCode          = Project.CompanyCode
  and      
   IsCommitment != 'X'
  and       not(
          (
            ControllingDebitCreditCode          = 'A'
          )
          or(
                  ControllingDebitCreditCode    = 'S'
            and(
                  BusinessTransactionType       = 'KOAO'
              or  BusinessTransactionType       = 'KOAE'
            )
            and(
                  PartnerProject                = ' '
              and PartnerOrder                  = ' '
              and PartnerSalesDocument          = ' '
              and PartnerProjectNetwork         = ' '
              and PartnerProjectNetworkActivity = ' '
              and PartnerBusinessProcess        = ' '
              and PartnerCostObject             = ' '
            )
          )
          or(
                  ControllingDebitCreditCode    = 'S'
            and(
                  BusinessTransactionType       = 'KOAO'
              or  BusinessTransactionType       = 'KOAE'
            )
            and(
                  PartnerProject                =  Project.Project
            )
          )
        )

group by
  Project.CompanyCode,  //

  Project.ProfitCenter, //

  Project.ControllingArea,
  ProjectUUID,
  ProjCstLineItm.ProjectInternalID,
  Project.ProjectType,
  FiscalYear,
  LedgerFiscalYear, //

  Project.Project,
  ControllingObjectCurrency,
  GlobalCurrency,
  FiscalPeriod,
  ProjCstLineItm.FiscalYearPeriod,
  ProjCstLineItm.PostingDate,
  ProjCstLineItm.GLAccount,
  ProjCstLineItm.ChartOfAccounts,
  Project.ProjectExternalID,
  Project.ProjectCurrency,
  Project._AvailabilityCtrlProfile.AvailyCtrlTimeRangeType,
  Project._AvailabilityCtrlProfile.BudgetCurrencyRole,
  //  SemanticTag.SemanticTag,

  ProjCstLineItm.AccountingDocument,
  ProjCstLineItm.LedgerGLLineItem,
  ProjectDescription,
  AvailabilityControlProfile,
  AvailabilityControlIsActive,
  AvailyCtrlTimeRangeType,
  BudgetCurrencyRole,
  ProjectSummaryTaskUUID,
  ProjCstLineItm.CreationDate