N_ChgRecdObjPgProdStrucVar

@AbapCatalog.sqlViewName: 'NCHGRECREFPSV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Record Reference Obj Page Product Structure Variant'
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   semanticKey: ['ProductStructureNodeName','Class','ProductStructureVariantName','ProdStrucVariantChangeNumber']
}
@Search.searchable: true

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XXL}
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdObjPgProdStrucVar'


define view N_ChgRecdObjPgProdStrucVar
  as select from           I_ChgRecdRefProdStrucVarBsc   as reference_psm
    left outer to one join I_ProductStructureVariantNode as _variant on  reference_psm.ChangeRecordRefObjectUUID = _variant.ProductStructureVariantUUID
                                                                     and reference_psm.ChgRecRefInternalKey4 = _variant.ProdStrucVariantChangeNumber

  association [0..1] to I_Classvh                      as _ClassVH                      on  $projection.Class = _ClassVH.Class
  association [0..1] to C_Nodevh                       as _NodeVH                       on  $projection.ProductStructureNodeName = _NodeVH.ProductStructureNodeName
  association [0..1] to C_Chgnrvh                      as _ChangeNumberVH               on  $projection.ProdStrucVariantChangeNumber = _ChangeNumberVH.ProdStrucVariantChangeNumber
  association [0..1] to C_ProductStructureVariantVH    as _VariantVH                    on  $projection.Class                        = _VariantVH.Class
                                                                                        and $projection.ProductStructureNodeName     = _VariantVH.ProductStructureNodeName
                                                                                        and $projection.ProductStructureVariantName  = _VariantVH.ProductStructureVariantName
                                                                                        and $projection.ProdStrucVariantChangeNumber = _VariantVH.ProdStrucVariantChangeNumber
  association [1..1] to C_ChgRecdItemRelProdStrucVarVH as _ChgRecdItemRelProdStrucVarVH on  $projection.ChangeRecordItemRelevance = _ChgRecdItemRelProdStrucVarVH.ChangeRecordItemRelevance
                                                                                        and $projection.ChangeRecordType          = _ChgRecdItemRelProdStrucVarVH.ChangeRecordType
                                                                                        and $projection.ChangeRecordReferenceType = _ChgRecdItemRelProdStrucVarVH.ChangeRecordReferenceType

  association [1..1] to C_ChangeRecordObjPg            as _ChangeRecordObjPg            on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

{

      @UI.hidden: true
      //@ObjectModel.readOnly: true

  key ChangeRecordReferenceUUID,
      @ObjectModel.foreignKey.association: '_ClassVH'
      @Consumption: { valueHelp: '_ClassVH' }
      @UI.identification: {position: 60, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:60,
                  importance:#HIGH }
                 ]
      Class,
      @ObjectModel.foreignKey.association: '_NodeVH'
      @UI.identification: {position: 40, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:40,
                  importance:#HIGH }
                 ]
      @EndUserText.label: 'Node'
      ProductStructureNodeName,
      @UI.identification: {position: 50, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:50,
                  importance:#HIGH }
                 ]
      @ObjectModel.readOnly: true
      ProdStrucNodeDescription,
      @UI.identification: {position: 10, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:10,
                  importance:#HIGH }
                 ]
      @ObjectModel.foreignKey.association: '_VariantVH'
      @Consumption: { valueHelp: '_VariantVH' }
      ProductStructureVariantName,
      @UI.identification: {position: 20, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:20,
                  importance:#HIGH }
                 ]
      @ObjectModel.readOnly: true
      ProdStrucVariantDescription,
      @UI.identification: {position: 30, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:30,
                  importance:#HIGH }
                 ]
      @ObjectModel.foreignKey.association: '_ChangeNumberVH'
      ProdStrucVariantChangeNumber,
      @UI.identification: {position: 70, importance: #HIGH}
      @UI.lineItem:[
       {
                  position:70,
                  importance:#HIGH }
                 ]
      @ObjectModel.readOnly: true
      Material,
      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_ChgRecdItemRelProdStrucVarVH'
      _ChangeRecordObjPg.ChangeRecordType                                                       as ChangeRecordType,
      @UI.hidden: true
      ChangeRecordUUID,
      @UI.hidden: true
      ChangeRecordReferenceType,
      @UI.hidden: true
      ParentChangeRecordRefUUID,
      @UI.lineItem:[{
                  position:80,
                  importance:#HIGH }
                ]
      @Consumption: { valueHelp: '_ChgRecdItemRelProdStrucVarVH' }
      @ObjectModel: {foreignKey.association: '_ChgRecdItemRelProdStrucVarVH' }
      @UI.identification: {position:80, importance: #HIGH}
      ChangeRecordItemRelevance,
      @UI.hidden: true
      ChangeRecordReference,
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      CreatedByUser,
      @UI.hidden: true
      CreationDateTime,
      @ObjectModel.virtualElement : true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
      @ObjectModel.readOnly: true
      cast( '00000000' as /plmb/created_on )                                                    as CreationDate,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      LastChangedByUser,

      @UI.hidden: true
      LastChangeDateTime,
      @ObjectModel.virtualElement : true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
      @ObjectModel.readOnly: true
      cast( '00000000' as /plmb/changed_on )                                                    as LastChangeDate,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChangeRecordObjPg.ChangeNumber,
      _ClassVH,
      _NodeVH,
      _VariantVH,
      _ChangeNumberVH,
      _ChgRecdItemRelProdStrucVarVH

}