MMIM_BSIM_PROXY

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'FI union view for MM-IM reporting'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
//Initial delivery with Note 3422716

define view entity MMIM_BSIM_PROXY
  as select from P_Materialledger_Curtp_Lit as it
    inner join   fmlv_logistic_currency     as f on  it.rbukrs = f.bukrs
                                                 and it.rldnr  = f.rldnr
{
  it.rbukrs                          as bukrs,
  it.bwkey,
  it.matnr,
  it.bwtar,
  --  it.drcrk as shkzg,
  case
    when it.hsl < 0 then 'H'
    when it.hsl = 0 and it.vmsl > 0 then 'S'
    when it.hsl = 0 and it.vmsl < 0 then 'H'
    else 'S'
  end                                as shkzg,
  it.rvunit                          as meins,
  it.budat,
  it.blart,
  cast( right(it.docln, 3) as buzei) as buzei,
  concat(it.awref, it.aworg)         as awkey,
  it.belnr,
  it.gjahr,
  @Semantics.quantity.unitOfMeasure: 'meins'
  cast(abs(it.vmsl) as menge_d)      as menge,
  @Semantics.amount.currencyCode: 'waers'
  abs(it.hsl)                        as dmbtr,
  //  case

  //    when it.vmsl = 0 then '0'

  //    when it.vmsl < 0 then '-'

  //    when it.vmsl > 0 then '+'

  //    else ''

  //  end                                as squan,

  it.awtyp,
  it.bldat,
  it.rhcur                           as waers,
  it.racct                           as hkont,
  tstmp_to_dats( it.timestamp,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                       'NULL' )      as cpudt,
  tstmp_to_tims( it.timestamp,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                       'NULL' )      as cputm,
  it.mat_kdauf,
  it.mat_kdpos,
  it.mat_pspnr,
  it.mat_lifnr                       as lifnr
}
where
      it.bstat <> 'D'
  and it.bstat <> 'M'
  and it.awtyp <> 'GLYEC'
  and it.matnr <> ''
-- and it.ktosl = 'BSX' this filter is not required here because P_Materialledger_Curtp_Lit does this filter already
-- and it.koart = 'M' not required at all because P_Materialledger_Curtp_Lit provides material with stock relation
-- Enrich with data from BSEG
union all select from P_ACDOCA               as it
  inner join          fmlv_logistic_currency as f on  it.rbukrs = f.bukrs
                                                  and it.rldnr  = f.rldnr
  inner join          bseg                   as b on  it.rbukrs = b.bukrs
                                                  and it.gjahr  = b.gjahr
                                                  and it.belnr  = b.belnr
                                                  and it.buzei  = b.buzei
{
  it.rbukrs                     as bukrs,
  b.bwkey,
  it.matnr,
  b.bwtar,
  b.shkzg,
  b.meins,
  it.budat,
  it.blart,
  it.buzei,
  b.awkey,
  it.belnr,
  it.gjahr,
  b.menge,
  b.dmbtr,
  //  b.squan,

  it.awtyp,
  it.bldat,
  it.rhcur                      as waers,
  it.racct                      as hkont,
  tstmp_to_dats( it.timestamp,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                       'NULL' ) as cpudt,
  tstmp_to_tims( it.timestamp,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                       'NULL' ) as cputm,
  b.vbeln                       as mat_kdauf,
  '000000'                      as mat_kdpos,
  b.projk                       as mat_pspnr,
  b.lifnr
}
where
  (
       it.mig_source =  'F'
    or it.mig_source =  'G'
  )
  and  it.bstat      <> 'C'
  and  it.bstat      <> 'D'
  and  it.bstat      <> 'M'
  and  it.awtyp      <> 'GLYEC'
  and  it.matnr      <> ''
  and  it.ktosl      =  'BSX'
  and  it.koart      =  'M'