MB5B_BSEG_PROXY

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'MB5B fetch FI data from ACDOCA'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
define view entity MB5B_BSEG_PROXY as
select from P_Materialledger_Curtp_Lit as it inner join fmlv_logistic_currency as f on  it.rbukrs = f.bukrs and it.rldnr  = f.rldnr
{
  it.rbukrs as bukrs,
  it.bwkey,
  it.matnr,
  it.bwtar,
--  it.drcrk as shkzg,
  case
    when it.hsl < 0 then 'H'
    when it.hsl = 0 and it.vmsl > 0 then 'S'
    when it.hsl = 0 and it.vmsl < 0 then 'H'
    else 'S'
  end as shkzg ,
  it.rvunit as meins,
  it.budat,
  it.blart,
  cast( right(it.docln, 3) as buzei) as buzei,
  concat(it.awref, it.aworg) as awkey,
  it.belnr,
  it.gjahr,
  @Semantics.quantity.unitOfMeasure: 'meins'
  cast(abs(it.vmsl) as menge_d) as menge,
  @Semantics.amount.currencyCode: 'waers'
  abs(it.hsl) as dmbtr,
  case
    when it.vmsl = 0 then '0'
    when it.vmsl < 0 then '-'
    when it.vmsl > 0 then '+'
    else ''
  end as squan ,
  it.awtyp,
  it.bldat,
  it.rhcur as waers,
  it.racct as hkont
}
where it.bstat <> 'D' and it.bstat <> 'M' and it.awtyp <> 'GLYEC' and it.matnr <> ''
-- and it.ktosl = 'BSX' this filter is not required here because P_Materialledger_Curtp_Lit does this filter already
-- and it.koart = 'M' not required at all because P_Materialledger_Curtp_Lit provides material with stock relation
-- Note 3421635 enrich with data from BSEG
union all select from P_ACDOCA               as it
  inner join          fmlv_logistic_currency as f on  it.rbukrs = f.bukrs
                                                  and it.rldnr  = f.rldnr
  inner join          bseg                   as b on  it.rbukrs = b.bukrs
                                                  and it.gjahr  = b.gjahr
                                                  and it.belnr  = b.belnr
                                                  and it.buzei  = b.buzei
{
  it.rbukrs as bukrs,
  b.bwkey,
  it.matnr,
  b.bwtar,
  b.shkzg,
  b.meins,
  it.budat,
  it.blart,
  it.buzei,
  b.awkey,
  it.belnr,
  it.gjahr,
  b.menge,
  b.dmbtr,
  b.squan,
  it.awtyp,
  it.bldat,
  it.rhcur  as waers,
  it.racct  as hkont
}
where
  (
       it.mig_source =  'F'
    or it.mig_source =  'G'
  )
  and  it.bstat      <> 'C'
  and  it.bstat      <> 'D'
  and  it.bstat      <> 'M'
  and  it.awtyp      <> 'GLYEC'
  and  it.matnr      <> ''
  and  it.ktosl      =  'BSX'
  and  it.koart      =  'M'