I_WorkflowApplCompText

DDL: I_WORKFLOWAPPLCOMPTEXT Type: view BASIC

Application Component Text

I_WorkflowApplCompText is a Basic CDS View that provides data about "Application Component Text" in SAP S/4HANA. It reads from 2 data sources (t100, df14t) and exposes 11 fields with key fields Language, SAPApplicationComponentId, ActivationStatus. It has 2 associations to related views.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
t100 t100 union_all
df14t Text from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_WorkflowApplComp _Component $projection.SAPApplicationComponentId = _Component.SAPApplicationComponentId and $projection.ActivationStatus = _Component.ActivationStatus
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName IWRKFLWAPPLCOMPT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.buffering.type #FULL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #META view
ObjectModel.dataCategory #TEXT view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Application Component Text view
VDM.viewType #BASIC view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey SAPApplicationComponentId view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY SAPApplicationComponentId df14t fctr_id
KEY ActivationStatus df14t as4local
SAPApplicationComponentText
Associations_Component
sprslasLanguage
SAPApplicationComponentId
ActivationStatus
SAPApplicationComponentText
Associations_Component
_Language _Language 
@AbapCatalog: {
  sqlViewName:            'IWRKFLWAPPLCOMPT',
  compiler.compareFilter: true,
  preserveKey: true,
  buffering: { type: #FULL }
}

@ObjectModel.usageType: {
  serviceQuality: #B,
  sizeCategory:   #S,
  dataClass:      #META
}


@ObjectModel: {
  dataCategory: #TEXT
}

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Application Component Text'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'SAPApplicationComponentId'
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_WorkflowApplCompText
  as select from df14t as Text

  association [0..1] to I_WorkflowApplComp as _Component on  $projection.SAPApplicationComponentId = _Component.SAPApplicationComponentId
                                                         and $projection.ActivationStatus          = _Component.ActivationStatus
  association [0..1] to I_Language         as _Language  on  $projection.Language = _Language.Language

{
      @Semantics:   { language: true }
      @ObjectModel: { foreignKey.association: '_Language' }
  key cast( Text.langu as ddlanguage preserving type )             as Language,
  key Text.fctr_id                                                 as SAPApplicationComponentId,
  key Text.as4local                                                as ActivationStatus,
      @Semantics:   { text: true }
      cast( Text.name as swf_flex_appl_comp_name preserving type ) as SAPApplicationComponentText,

      -------------------------------------------------------------------------------------------------
      -- Associations                                                                                --
      -------------------------------------------------------------------------------------------------
      _Component,
      _Language
}
union all select from t100
association [0..1] to I_WorkflowApplComp as _Component on  $projection.SAPApplicationComponentId = _Component.SAPApplicationComponentId
                                                       and $projection.ActivationStatus          = _Component.ActivationStatus
association [0..1] to I_Language         as _Language  on  $projection.Language = _Language.Language
{
  t100.sprsl                                                                       as Language,
  'LOCAL'                                                                          as SAPApplicationComponentId,
  ''                                                                               as ActivationStatus,
  cast( substring( t100.text, 1, 60 ) as swf_flex_appl_comp_name preserving type ) as SAPApplicationComponentText,

  -------------------------------------------------------------------------------------------------
  -- Associations                                                                                --
  -------------------------------------------------------------------------------------------------
  _Component,
  _Language
}
where
      t100.arbgb = 'SWF_FLEX_IFS'
  and t100.msgnr = '024'

Learn More