I_WorkPermitOrder

@AbapCatalog.sqlViewName: 'IWORKPERMITOR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Work Permit Assigned Orders'
@VDM.viewType: #BASIC
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   }
}
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_WorkPermitOrder
  as select from I_WorkPermitOrderBasic as _WorkPermitOrderBasic
    inner join   I_WorkPermitBasic      as _WorkPermitBasic on _WorkPermitBasic.WorkPermitInternalID = _WorkPermitOrderBasic.WorkPermitInternalID
  association [1..1] to I_MaintenanceOrder         as _MaintenanceOrder     on $projection.MaintenanceOrderInternalID = _MaintenanceOrder.MaintenanceOrderInternalID
  association [0..1] to I_MaintenancePlanPlant        as _MaintenancePlanPlant       on  $projection.maintenanceplanningplant = _MaintenancePlanPlant.MaintenancePlanningPlant
  association [1..1] to I_OrderType                   as _MaintenanceOrderType       on  $projection.maintenanceordertype = _MaintenanceOrderType.OrderType    
{
  key _WorkPermitOrderBasic.MaintenanceOrderInternalID,
  key _WorkPermitOrderBasic.WorkPermitInternalID,
      _WorkPermitBasic.WorkPermit,
      _WorkPermitBasic.WrkPermitDesc,
      _MaintenanceOrder.MaintenanceOrder,
      _MaintenanceOrder.MaintenanceOrderDesc,
      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
      _MaintenanceOrder.MaintenancePlanningPlant,
      @ObjectModel.foreignKey.association: '_MaintenanceOrderType'
      _MaintenanceOrder.MaintenanceOrderType,
      _MaintenanceOrder.MaintOrderRoutingNumber,
      _WorkPermitOrderBasic.WorkPermitOrderObjectType,
      _WorkPermitOrderBasic.WorkPermitObjectType,
      _WorkPermitOrderBasic.WrkPmtProcessingContext,           
      cast ('' as vdm_j_system_status_concat_t) as MaintOrdCnctntdActvSystSts,
      _MaintenanceOrder  ,
      _MaintenancePlanPlant,
      _MaintenanceOrderType      
}