I_WorkCenterActivityTexts

//@AbapCatalog.sqlViewName: 'IWRKCNTRACTDESCR'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
//@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'WorkCenterInternalID'
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #M, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Work Center Activity Descriptions'

//define view I_WorkCenterActivityTexts 

define view entity I_WorkCenterActivityTexts 
  as select from P_WorkCenterActivity2 as wrkctract
  
{
  // Technical key

  key WorkCenterInternalID,
  @ObjectModel.foreignKey.association: '_WorkCenterType'
  key WorkCenterTypeCode,
  
  // Semantic key

  @ObjectModel.foreignKey.association: '_WorkCenterCategory'
  WorkCenterCategoryCode,  
  @ObjectModel.foreignKey.association: '_WorkCenter'
  WorkCenter,
  @ObjectModel.foreignKey.association: '_Plant'
  Plant,

  // Determination activity texts

  @Semantics.text: true
  case coalesce( ActivityDescOriginType1, '' )
    when '' then                       // description of parameter from standard value key

      ParamName1
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName1
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc1
    else ''     
  end as WorkCenterActivityText1,

  @Semantics.text: true
  case coalesce( ActivityDescOriginType2, '' )
    when '' then                       // description of parameter from standard value key

      ParamName2
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName2
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc2
    else ''     
  end as WorkCenterActivityText2,

  @Semantics.text: true
  case coalesce( ActivityDescOriginType3, '' )
    when '' then                       // description of parameter from standard value key

      ParamName3
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName3
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc3
    else ''     
  end as WorkCenterActivityText3,

  @Semantics.text: true
  case coalesce( ActivityDescOriginType4, '' )
    when '' then                       // description of parameter from standard value key

      ParamName4
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName4
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc4
    else ''     
  end as WorkCenterActivityText4,

  @Semantics.text: true
  case coalesce( ActivityDescOriginType5, '' )
    when '' then                       // description of parameter from standard value key

      ParamName5
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName5
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc5           
    else ''     
  end as WorkCenterActivityText5,

  @Semantics.text: true
  case coalesce( ActivityDescOriginType6, '' )
    when '' then                       // description of parameter from standard value key

      ParamName6
    when '0' then                      // no description

      '' 
    when '1' then                      // description of activity type

      CostCtrActivityTypeName6
    when '2' then                      // description of activity from customizing

      CostCenterActivityAltvDesc6           
    else ''     
  end as WorkCenterActivityText6,

  // Associations

  _WorkCenter,
  _WorkCenterType,
  _WorkCenterCategory,
  _Plant

};