I_WorkAssignmentValueHelp

@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck:#MANDATORY
@EndUserText.label: 'Work Assignments of a Workforce Person'
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true 
@Consumption.ranked: true
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey:'WorkAssignment'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MASTER
} 

 define view entity I_WorkAssignmentValueHelp as select from I_WorkAssignmentKeyMapping as keymap                                      
      inner join I_WorkAssignmentDetailsAll as dets       on keymap.WorkAssignment                = dets.WorkAssignment and
                                                             dets.WorkAssignmentStatus            = '1'
      inner join I_WorkAssignmentBP as WrkAssgmtBP        on WrkAssgmtBP.WorkAssignment           = keymap.WorkAssignment
      inner join I_BusinessPartner  as EmploymentBP       on EmploymentBP.BusinessPartner         = WrkAssgmtBP.WorkAssignmentBusinessPartner
                                                         and EmploymentBP.BusinessPartnerCategory = '1'
      left outer to one join I_BusinessUserBasic as User  on User.BusinessPartner                 = keymap.BusinessPartner
      left outer to one join I_CompanyCode as CompanyCode on dets.CompanyCode                     = CompanyCode.CompanyCode
      left outer to one join I_CostCenter  as CostCenter  on dets.CostCenter                      = CostCenter.CostCenter
                                                         and dets.CompanyCode                     = CostCenter.CompanyCode
                                                         and CostCenter.ValidityEndDate          >= dets.WorkAssignmentEndDate
                                                         and CostCenter.ValidityStartDate        <= dets.WorkAssignmentEndDate 
      left outer to one join I_PersonWorkAgrmtJobText as JobText on JobText.Job                   = dets.WorkforcePersonJobCode
                                                         and JobText.EndDate                     >= dets.WorkAssignmentEndDate
                                                         and JobText.StartDate                   <= dets.WorkAssignmentEndDate  
                                                         and JobText.Language                     = $session.system_language 
  {
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }       
  key keymap.WorkAssignment, 
  key dets.WorkAssignmentStartDate,
      dets.WorkAssignmentEndDate,
      keymap.BusinessPartner,
      @EndUserText.label: 'Last Name'
      EmploymentBP.LastName,
      @EndUserText.quickInfo: 'Family Name'
      @EndUserText.label: 'Family Name'
      EmploymentBP.BPLastNameSearchHelp as FamilyName,
      @EndUserText.label: 'First Name'
      EmploymentBP.FirstName,
      @EndUserText.quickInfo: 'Given Name'
      @EndUserText.label: 'Given Name'
      EmploymentBP.BPFirstNameSearchHelp as GivenName, 
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }          
      keymap.WorkforcePersonExternalID,
      keymap.WorkAssignmentExternalID, 
      User.UserID,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }     
      @Semantics.text: true
      EmploymentBP.PersonFullName,
      dets.CompanyCode,
      CompanyCode.CompanyCodeName,
      dets.CostCenter,
      CostCenter._Text[1: Language =  $session.system_language ].CostCenterName,
      dets.WorkforcePersonJobCode as Job,      
      @EndUserText.label: 'Job Name'      
      JobText.JobName as JobName,
      dets.Country2DigitISOCode,      
      @UI.hidden      
      EmploymentBP.AuthorizationGroup as AuthorizationGroup,
      @UI.hidden
      @Semantics.booleanIndicator: true 
      EmploymentBP.IsBusinessPurposeCompleted,
      keymap.IsBlocked,
      
      //Added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataControllerSet,                                                                                                                                                                      
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController5,                                                                                                                                                                       
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController8,
      @Consumption.hidden:true
      @UI.hidden:true 
      EmploymentBP.DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      EmploymentBP.DataController10
         
};