I_UtilsAccountDetnCodeText

@EndUserText.label: 'Account Determination Code - Text'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEACCTDETNCODET'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: { supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE ]
              }
@Analytics: {  dataExtraction: { enabled: true } }
@Metadata.ignorePropagatedAnnotations:true
//@AbapCatalog.preserveKey:true

@AbapCatalog.compiler.compareFilter:true
@ObjectModel.representativeKey: 'UtilitiesAccountDetnCode'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT

define view I_UtilsAccountDetnCodeText
  as select from te097t
  association [0..1] to I_Language             as _Language             on  $projection.Language = _Language.Language
  association [1..1] to I_UtilsAccountDetnCode as _UtilsAccountDetnCode on  $projection.CompanyCode              = _UtilsAccountDetnCode.CompanyCode
                                                                        and $projection.Division                 = _UtilsAccountDetnCode.Division
                                                                        and $projection.UtilitiesAccountDetnCode = _UtilsAccountDetnCode.UtilitiesAccountDetnCode
  association [0..1] to I_CompanyCode          as _CompanyCode          on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Division             as _Division             on  $projection.Division = _Division.Division
{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key te097t.spras                                             as Language,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key te097t.bukrs                                             as CompanyCode,
      @ObjectModel.foreignKey.association: '_Division'
  key te097t.sparte                                            as Division,
  key cast(te097t.kofiz  as e_kofiz_vdm      preserving type ) as UtilitiesAccountDetnCode,
      @Semantics.text: true
      cast(te097t.text50 as e_kofiz_name_vdm preserving type)  as UtilitiesAccountDetnCodeName,

      _Language,
      _UtilsAccountDetnCode,
      _CompanyCode,
      _Division
}