I_TriggerPointText

@AbapCatalog.sqlViewName: 'ITRIGGERPTTEXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'TriggerPointNumber'
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Trigger Point - Text'

define view I_TriggerPointText
  as select from I_Projectmilestonetext as text
      inner join I_Projectmilestone     as mlst on mlst.ProjectMilestone = text.ProjectMilestone
  
--  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @ObjectModel.text.element: ['TriggerPointName']
  key cast(text.ProjectMilestone as pph_mlst_zaehl preserving type)     as TriggerPointNumber, 
      @Semantics.language : true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(text.Language as spras preserving type)                      as Language,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(text.MilestoneDescription as pph_mlst_ktext preserving type) as TriggerPointName,

      @Consumption.hidden: true // for DCLS

      mlst.OrderCategory,

      // Associations

      text._Language
}
where mlst.OrderCategory = '10'
   or mlst.OrderCategory = '40';