I_TrdgContractItemBasicData

@AbapCatalog.sqlViewName: 'ITRDCNTRITMDATA'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.compiler.compareFilter:true

@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@EndUserText.label: 'Basic contract item data'
@Metadata.ignorePropagatedAnnotations: true
define view I_TrdgContractItemBasicData as select from wbhi as ContrItem
  inner join wbhk                  as ContractHeader on ContrItem.tkonn   = ContractHeader.tkonn
  inner join P_TradingContractType as ContractType   on ContractHeader.tctyp = ContractType.tctyp
  inner join   wbhd                as Business       on ContractHeader.tkonn = Business.tkonn and Business.tposn = '000000'
  inner join   mara                as Material       on ContrItem.matnr = Material.matnr {

  key ContrItem.tkonn     as ContractNum,
  key ContrItem.tposn     as TradingContractItem,
  key ContrItem.tposn_sub as ContractSubItem,
      werks     as ContractPlant,
      lgort     as ContractStorageLocation,
      ContrItem.matnr     as ContractMaterial,
      case ContractType.Side
      when 'P' then ContrItem.meins
      when 'S' then ContrItem.vrkme
      end as TrdgContractItemUnitOfMeasure,
      $session.client as SAPClient,
      company_code as CompanyCode,
      ContractHeader.tctyp as TradingContractType,
      Material.commodity as Commodity,
      ContractHeader.kunnr as CustomerName,
      Business.elifn       as SupplierName
}