@EndUserText.label: 'Transportation Order Analytics'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {allowExtensions: true,
ignorePropagatedAnnotations: true}
@AbapCatalog: {sqlViewName: 'ITRANSPORDANA',
compiler.compareFilter: true,
buffering: {status: #NOT_ALLOWED},
preserveKey: true}
@AccessControl: {authorizationCheck: #CHECK,
privilegedAssociations: [ '_CreatedBy' ],
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {representativeKey: 'TransportationOrderUUID',
usageType: {serviceQuality: #D,
sizeCategory: #XXL,
dataClass: #MIXED},
modelingPattern: #NONE,
supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET,
#SQL_DATA_SOURCE,
#EXTRACTION_DATA_SOURCE,
#ANALYTICAL_PROVIDER,
#ANALYTICAL_DIMENSION]}
@VDM: {viewType: #COMPOSITE}
@Analytics: {dataCategory: #DIMENSION,
dataExtraction: {enabled: true,
delta.changeDataCapture:
{ mapping:[
{ table: '/scmtms/d_torrot',
role: #MAIN,
viewElement: ['TransportationOrderUUID'],
tableElement: ['db_key'] } ] } },
internalName: #LOCAL}
define view I_TransportationOrderAnalytics
as select from I_TransportationOrder
association [0..*] to I_TranspOrdItemAnalytics as _TranspOrdItemAnalytics on $projection.TransportationOrderUUID = _TranspOrdItemAnalytics.TransportationOrderUUID
association [0..*] to I_TranspOrdStopAnalytics as _TranspOrdStopAnalytics on $projection.TransportationOrderUUID = _TranspOrdStopAnalytics.TransportationOrderUUID
association [0..*] to I_TranspOrdStageAnalytics as _TranspOrdStageAnalytics on $projection.TransportationOrderUUID = _TranspOrdStageAnalytics.TransportationOrderUUID
association [0..*] to I_TranspOrdExecutionAnalytics as _TranspOrdExecutionAnalytics on $projection.TransportationOrderUUID = _TranspOrdExecutionAnalytics.TransportationOrderUUID
{
/* Keys */
@Semantics.uuid: true
key TransportationOrderUUID,
/* Order Details */
cast (TransportationOrder as /scmtms/vdm_tor_id preserving type) as TransportationOrder,
@ObjectModel.foreignKey.association: '_TransportationOrderCategory'
cast (TransportationOrderCategory as /scmtms/vdm_tor_category preserving type) as TransportationOrderCategory,
@ObjectModel.foreignKey.association: '_TransportationOrderType'
cast (TransportationOrderType as /scmtms/vdm_tor_type preserving type) as TransportationOrderType,
cast( cast(1 as abap.dec(10,0)) as /scmtms/vdm_num_tor preserving type) as NumberOfTransportationOrders,
/* Admin */
@Semantics.user.createdBy: true
@ObjectModel.foreignKey.association: '_CreatedBy'
CreatedByUser,
cast(CreationDateTime as /scmtms/vdm_creation_datetme preserving type ) as TranspOrdCreationDateTime,
@Semantics.businessDate.at: true
cast(cast(substring(cast(CreationDateTime as abap.char(17)), 1, 8) as abap.dats) as /scmtms/vdm_creation_date preserving type) as TranspOrdCreationDate,
@Semantics.user.lastChangedBy: true
LastChangedByUser,
cast(ChangedDateTime as /scmtms/vdm_tm_tstmp_cht preserving type ) as ChangedDateTime,
cast(TranspOrdLfcycStsChgDteTime as /scmtms/vdm_lc_sts_chg_dttme_n preserving type ) as TranspOrdLfcycStsChgDteTime,
cast(TranspOrdOrderDateTime as /scmtms/vdm_tor_order_datetime preserving type) as TranspOrdOrderDateTime,
/* Attributes */
TranspOrdPartnerReference,
cast (TranspOrdResponsiblePerson as /scmtms/vdm_tor_resp_person preserving type) as TranspOrdResponsiblePerson,
cast (DangerousGoodsAreContained as /scmtms/vdm_tor_dang_goods_ind preserving type) as DangerousGoodsAreContained,
TransportationServiceLevel,
/* Block Information */
@ObjectModel.foreignKey.association: '_TranspOrdPlanningBlock'
cast(TranspOrdPlanningBlock as /scmtms/vdm_block_planning preserving type) as TranspOrdPlanningBlock,
@Semantics.booleanIndicator:true
@ObjectModel.foreignKey.association: '_TranspOrdExecutionIsBlocked'
cast(TranspOrdExecutionIsBlocked as /scmtms/vdm_block_execution preserving type) as TranspOrdExecutionIsBlocked,
@Semantics.booleanIndicator:true
@ObjectModel.foreignKey.association: '_InvoicingIsBlocked'
cast(InvoicingIsBlocked as /scmtms/vdm_block_invoicing preserving type) as InvoicingIsBlocked,
/* Business Partner */
@ObjectModel.foreignKey.association: '_Carrier'
Carrier,
@Semantics.uuid: true
cast(CarrierUUID as /scmtms/vdm_carrier_party_key preserving type ) as CarrierUUID,
cast(CarrierAddressID as /scmtms/vdm_carrier_address_id preserving type ) as CarrierAddressID,
@ObjectModel.foreignKey.association: '_CarrierOriginOfEntry'
cast(CarrierOriginOfEntry as /scmtms/vdm_carr_entry_origin preserving type ) as CarrierOriginOfEntry,
@ObjectModel.foreignKey.association: '_TranspSCACCode'
// cast to TranspSCACCode in using views necessary as StandardCarrierAlphaCode will be deprecated
StandardCarrierAlphaCode,
@ObjectModel.foreignKey.association: '_TranspAirlineIATACode'
TranspOrdAirlineIATACode,
cast(TranspOrdAirWayBill as /scmtms/vdm_airlcawb preserving type ) as TranspOrdAirWayBill,
cast(MasterBillOfLading as /scmtms/vdm_mbl_number preserving type ) as MasterBillOfLading,
@ObjectModel.foreignKey.association: '_Shipper'
Shipper,
@Semantics.uuid: true
cast(ShipperUUID as /scmtms/vdm_shipper_party_key preserving type ) as ShipperUUID,
cast(ShipperAddressID as /scmtms/vdm_shipper_address_id preserving type ) as ShipperAddressID,
@ObjectModel.foreignKey.association: '_Consignee'
Consignee,
@Semantics.uuid: true
cast(ConsigneeUUID as /scmtms/vdm_consignee_key preserving type ) as ConsigneeUUID,
cast(ConsigneeAddressID as /scmtms/vdm_consignee_addr_id preserving type ) as ConsigneeAddressID,
@ObjectModel.foreignKey.association: '_TranspOrdShippingType'
TranspOrdShippingType,
@ObjectModel.foreignKey.association: '_MovementType'
MovementType,
@ObjectModel.foreignKey.association: '_TranspOrdTrafficDirection'
TranspOrdTrafficDirection,
/* OrgUnits for DCL, without foreign key association */
cast(_PlngAndExecOrganization.OrganizationalUnitExternalID as /scmtms/exec_org_ext_id preserving type) as PlngAndExecOrgExternalID,
cast(_PlngAndExecGroup.OrganizationalUnitExternalID as /scmtms/exec_grp_ext_id preserving type) as PlngAndExecGroupExternalID,
cast(PurchasingOrgExternalID as /scmb/pur_org_ext_id preserving type) as PurchasingOrgExternalID,
cast(PurchasingGroupExternalID as /scmb/egrp_org_ext_id preserving type) as PurchasingGroupExternalID,
/* Status Information */
@ObjectModel.foreignKey.association: '_TranspOrdLifeCycleStatus'
cast(TranspOrdLifeCycleStatus as /scmtms/vdm_tor_lc_status preserving type) as TranspOrdLifeCycleStatus,
@ObjectModel.foreignKey.association: '_TranspOrdPlanningStatus'
cast(TranspOrdPlanningStatus as /scmtms/vdm_tor_pln_status preserving type) as TranspOrdPlanningStatus,
@ObjectModel.foreignKey.association: '_TransportationOrderExecSts'
cast(TransportationOrderExecSts as /scmtms/vdm_tor_exe_sts preserving type) as TransportationOrderExecSts,
@ObjectModel.foreignKey.association: '_TranspOrdDngrsGdsStatus'
cast(TranspOrderDngrsGdsSts as /scmtms/vdm_tor_dg_status preserving type) as TranspOrderDngrsGdsSts,
@ObjectModel.foreignKey.association: '_TranspOrdSubcontractingSts' // --> not yet C1 released
TranspOrderSubcontrgSts,
// @ObjectModel.foreignKey.association: '_TranspOrdConfirmationStatus' --> not yet C1 released
TransportationOrderConfSts,
// @ObjectModel.foreignKey.association: '_TranspOrdGoodsMvtStatus' --> not yet C1 released
cast(TranspOrdGoodsMovementStatus as /scmtms/vdm_dlv_goods_mvt_sts preserving type) as TranspOrdGoodsMovementStatus,
// @ObjectModel.foreignKey.association: '_TranspOrdWhseProcgStatus' --> not yet C1 released
cast(TranspOrdWhseProcessingStatus as /scmtms/vdm_wh_procg_status preserving type) as TranspOrdWhseProcessingStatus,
/* Documents */
BusinessTransactionDocument,
BusinessTransactionDocType,
TransportationRequestCategory,
/* Transportation Information */
@ObjectModel.foreignKey.association: '_MeansOfTransport'
// cast as TranspOrdMeansOfTransport in using views necessary (C1 incompatible here)
cast(MeansOfTransport as /scmtms/vdm_tor_mot preserving type) as MeansOfTransport,
@ObjectModel.foreignKey.association: '_TransportationMode'
cast(TransportationMode as /scmtms/vdm_tor_trmodcode preserving type) as TransportationMode,
@ObjectModel.foreignKey.association: '_TransportationModeCategory'
cast(TransportationModeCategory as /scmtms/vdm_tor_trmod_cat preserving type) as TransportationModeCategory,
/*Dispute*/
@ObjectModel.foreignKey.association: '_FrtDsputCaseStatus'
cast(FrtDsputCaseStatus as /scmtms/vdm_inv_disp_status preserving type) as FrtDsputCaseStatus,
/* Ratio in Percent */
@DefaultAggregation: #MAX
@Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
TranspOrdMaxUtilznRatio, // contains Max value of Mass and Volume and Length Ratio
@DefaultAggregation: #MAX
@Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
cast(TranspOrdMaxUtilznMassRatio as /scmtms/vdm_tor_max_util_mass preserving type) as TranspOrdMaxUtilznMassRatio,
@DefaultAggregation: #MAX
@Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
cast(TranspOrdMaxUtilznVolumeRatio as /scmtms/vdm_max_util_volume preserving type) as TranspOrdMaxUtilznVolumeRatio,
@DefaultAggregation: #MAX
@Semantics.quantity.unitOfMeasure: 'TranspOrdUtilznUnit'
cast(TranspOrdMaxUtilznLengthRatio as /scmtms/vdm_max_util_length preserving type) as TranspOrdMaxUtilznLengthRatio,
@Semantics.unitOfMeasure: true
cast(cast('%' as abap.unit(3)) as /scmtms/vdm_util_percent_unit preserving type) as TranspOrdUtilznUnit,
/* Measures and Units */
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
cast(TranspOrdGrossWeight as /scmtms/vdm_tor_gro_wei_val preserving type ) as TranspOrdGrossWeight,
@ObjectModel.foreignKey.association: '_TranspOrdGrossWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdGrossWeightUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
cast(TranspOrdGrossVolume as /scmtms/vdm_tor_gro_vol_val preserving type) as TranspOrdGrossVolume,
@ObjectModel.foreignKey.association: '_TranspOrdGrossVolumeUnit'
@Semantics.unitOfMeasure: true
TranspOrdGrossVolumeUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdNetWeightUnit'
cast(TranspOrdNetWeight as /scmtms/vdm_tor_net_wei_val preserving type) as TranspOrdNetWeight,
@ObjectModel.foreignKey.association: '_TranspOrdNetWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdNetWeightUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdTareWeightUnit'
cast(TranspOrdTareWeight as /scmtms/vdm_tor_pack_unl_wei_v preserving type) as TranspOrdTareWeight,
@ObjectModel.foreignKey.association: '_TranspOrdTareWeightUnit'
@Semantics.unitOfMeasure: true
TranspOrdTareWeightUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
cast(TranspOrdQuantity as /scmtms/vdm_tor_pcs_val preserving type) as TranspOrdQuantity,
@ObjectModel.foreignKey.association: '_TranspOrdQuantityUnit'
@Semantics.unitOfMeasure: true
TranspOrdQuantityUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdNumberOfCtnsUnit'
cast(TranspOrdNumberOfCtns as /scmtms/vdm_tor_cont_count_val preserving type) as TranspOrdNumberOfCtns,
@ObjectModel.foreignKey.association: '_TranspOrdNumberOfCtnsUnit'
@Semantics.unitOfMeasure: true
TranspOrdNumberOfCtnsUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdDngrsGdsExmpPtsUnit'
cast(TranspOrdDngrsGdsExmpPts as /scmtms/vdm_tor_dg_adr_pts_val preserving type) as TranspOrdDngrsGdsExmpPts,
@ObjectModel.foreignKey.association: '_TranspOrdDngrsGdsExmpPtsUnit'
@Semantics.unitOfMeasure: true
TranspOrdDngrsGdsExmpPtsUnit,
@DefaultAggregation: #SUM
@Semantics.quantity.unitOfMeasure: 'TranspOrdDistanceUnit'
cast(TranspOrdDistance as /scmtms/vdm_total_distance_km) as TranspOrdDistance,
@Semantics.unitOfMeasure: true
cast(TranspOrdDistanceUnit as /scmtms/vdm_tor_dstnc_unit preserving type) as TranspOrdDistanceUnit,
cast (TranspOrdNetDuration as /scmtms/vdm_tor_net_duration preserving type) as TranspOrdNetDuration,
/* Associations */
_TranspOrdItemAnalytics,
_TranspOrdStopAnalytics,
_TranspOrdStageAnalytics,
_TranspOrdExecutionAnalytics,
_Carrier,
_CarrierOriginOfEntry,
_Shipper,
_Consignee,
/* Codelist Associations */
_TransportationOrderCategory,
_TransportationOrderType,
_CreatedBy,
_TranspOrdPlanningBlock,
_TranspOrdExecutionIsBlocked,
_InvoicingIsBlocked,
_TranspSCACCode,
_TranspAirlineIATACode,
_TranspOrdShippingType,
_MovementType,
_TranspOrdTrafficDirection,
_TranspOrdLifeCycleStatus,
_TranspOrdPlanningStatus,
_TransportationOrderExecSts,
_TranspOrdDngrsGdsStatus,
_TranspOrdSubcontractingSts,
// _TranspOrdConfirmationStatus,
// _TranspOrdGoodsMvtStatus,
// _TranspOrdWhseProcgStatus,
_MeansOfTransport,
_TransportationMode,
_TransportationModeCategory,
_FrtDsputCaseStatus,
/* Units */
_TranspOrdGrossWeightUnit,
_TranspOrdGrossVolumeUnit,
_TranspOrdQuantityUnit,
_TranspOrdNetWeightUnit,
_TranspOrdTareWeightUnit,
_TranspOrdNumberOfCtnsUnit,
_TranspOrdDngrsGdsExmpPtsUnit
}