I_TradingContractItemOverview

@AbapCatalog.sqlViewName: 'ITRDGCONTRITEM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.supportedCapabilities: #CDS_MODELING_DATA_SOURCE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Interface View For Contract Item Overview'
define view I_TradingContractItemOverview
  as select from    I_ACMTradingContractItemData           as Item
  left outer to one join I_ACMMaterialDetailsText          as MatlDesc       on MatlDesc.Product = Item.ContractMaterial /*Adding Material Description */
                                                                             and MatlDesc.Language  =  $session.system_language
  left outer to one join I_ACMMaterialDetails              as MatlDet        on MatlDet.Product =  MatlDesc.Product

  inner join      I_ACMContractCommoditySubitem            as CommodityItem  on  Item.TradingContractNumber = CommodityItem.TradingContractNumber
                                                                             and Item.TradingContractItem   = CommodityItem.TradingContractItem
  inner join      I_CmmdtyText                             as CommodityDesc  on  MatlDet.PhysicalCommodity = CommodityDesc.Commodity
                                                                                                          and CommodityDesc.Language = $session.system_language
    left outer join I_PlantStdVH                           as _Plant         on Item.ContractPlant = _Plant.Plant
    left outer join I_ACMTradingContractData               as Header         on Header.ContractNum = Item.TradingContractNumber

    left outer join I_ACMContractItemAddldata              as _AddlData      on  Item.TradingContractNumber = _AddlData.TradingContractNumber
                                                                             and Item.TradingContractItem   = _AddlData.TradingContractItem
    left outer join P_GenericDomainVH( p_domain_name: '/ACCGO/D_INTENDED_PRICE_TYPE') as IntendedPriceType on IntendedPriceType.DomainValue = upper(
      ACMPrcgIntendedPrcType
    )
    left outer to one join I_ACMTrdgContractBusinessData   as Business on Business.TradingContractNumber = Item.TradingContractNumber
    left outer to one join P_TradingContractCounterparty   as Counterparty on Counterparty.Counterparty = Business.PurchaseOrderSupplier

{
  key Item.TradingContractNumber                                               as TradingContractNumber,
  key Item.TradingContractItem                                                 as TradingContractItem,
      ltrim(Item.ContractMaterial, '0')                                        as ContractMaterial,
      MatlDesc.ProductDescription                                              as MaterialDesc,
      MatlDesc._Material.PhysicalCommodity                                     as ContractCommodityItem,
      CommodityDesc.CommodityName                                              as CommodityName,
      CommodityItem.TrdgContrCreditSalesFromDate                               as ActualStartDateFrom,
      CommodityItem.TrdgContractCreditSalesToDate                              as ActualStartDateTo,
      Item.ContractPlant                                                       as ContractPlant,
      _Plant.PlantName                                                         as PlantName,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      CommodityItem.ACMPricingCancellationQuantity                             as CommodityQuantity,
      @Semantics.unitOfMeasure: true
      CommodityItem.TrdgContractItemUnitOfMeasure                              as UnitOfMeasure,
      Header.TradingContractType                                               as TradingContractType,
      Header.CompanyCode                                                       as CompanyCode,
      cast(concat('0000000000', Item.TradingContractNumber) as cmm_vlogp_root) as OriginReferenceDocument,
      _AddlData.ValuationPoint                                                 as ValuationPoint,
      cast( IntendedPriceType.DomainValue as  /accgo/e_intended_price_type )   as ACMPrcgIntendedPrcType,
      Counterparty.Counterparty                                                as Counterparty,
      @Semantics.booleanIndicator: true
      Counterparty.IsBusinessPurposeCompleted                                  as IsBusinessPurposeCompleted,
      Counterparty.AuthorizationGroup                                          as AuthorizationGroup
}