I_SupDmndAllDocOpenDeliveries

DDL: I_SUPDMNDALLDOCOPENDELIVERIES Type: view BASIC

View for Open Deliveries

I_SupDmndAllDocOpenDeliveries is a Basic CDS View that provides data about "View for Open Deliveries" in SAP S/4HANA. It reads from 4 data sources (kna1, lips, I_SupDmndMaterialPlant, vbbe) and exposes 38 fields.

4 data source(s) 38 fields

Data Sources (4)

SourceAliasJoin Type
kna1 kna1 inner
lips lips inner
I_SupDmndMaterialPlant marc inner
vbbe vbbe inner

Annotations (10)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #NOT_REQUIRED view
AbapCatalog.sqlViewName ISUPDMNDADODLV view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #XXL view
EndUserText.label View for Open Deliveries view

Fields (38)

KeyFieldSource TableSource FieldDescription
RequirementDocumentNumber vbbe vbeln
RequirementDocumentItem vbbe posnr
HigherLvlItmOfBatSpltItm lips uecha
RequirementType
RequestedDate vbbe mbdat
ProductAvailabilityDate vbbe mbdat
RequestedDeliveryDate vbbe mbdat
DeliveredQuantity vbbe omeng
BaseUnit vbbe meins
DeliveryTimeInDays
NumberOfDays
ShippingType likp vsart
Material vbbe matnr
Plant vbbe werks
MaterialGroup lips matkl
MaterialType I_SupDmndMaterialPlant MaterialType
CrossPlantConfigurableProduct I_SupDmndMaterialPlant CrossPlantConfigurableProduct
RequirementSegment lips sgt_rcat
SDDocumentCategory likp vbtyp
DeliveryDocumentType likp lfart
SalesOrganization likp vkorg
DistributionChannel lips vtweg
Division lips spart
SalesDistrict likp bzirk
SoldToParty likp kunag
StorageLocation vbbe lgort
SalesDocument vbbe vbele
SalesDocumentItem vbbe posne
chargelseendasBatch
InventorySpecialStockType vbbe sobkz
Reservation lips fsh_rsnum
ReservationItem lips fsh_rspos
IsBusinessPurposeCompleted kna1 cvp_xblck
NetPriceAmount lips netpr
DocumentCurrency likp waerk
ReferenceSDDocument vgbel
ReferenceSDDocumentItem vgpos
ReferenceSDDocumentCategory vgtyp 
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADODLV',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
@EndUserText.label: 'View for Open Deliveries'
define view I_SupDmndAllDocOpenDeliveries
  as select distinct from
                          likp                   as likp
    inner join            lips                   as lips on  likp.vbeln = lips.vbeln
    inner join            vbbe                   as vbbe on  lips.vbeln = vbbe.vbeln
                                                         and lips.posnr = vbbe.posnr
    inner join            I_SupDmndMaterialPlant as marc on  vbbe.matnr = marc.Material
                                                         and vbbe.werks = marc.Plant
    inner join            kna1                   as kna1 on likp.kunnr = kna1.kunnr
{
  vbbe.vbeln                                                                 as RequirementDocumentNumber,
  vbbe.posnr                                                                 as RequirementDocumentItem,
  lips.uecha                                                                 as HigherLvlItmOfBatSpltItm,
  'VJ'                                                                       as RequirementType,
  vbbe.mbdat                                                                 as RequestedDate,
  vbbe.mbdat                                                                 as ProductAvailabilityDate,
  vbbe.mbdat                                                                 as RequestedDeliveryDate,
  vbbe.omeng                                                                 as DeliveredQuantity,
  vbbe.meins                                                                 as BaseUnit,
  dats_days_between( vbbe.mbdat, cast( $session.system_date as abap.dats ) ) as DeliveryTimeInDays,
  // Planned GI Date - Current Date

  dats_days_between( likp.wadat, cast( $session.system_date as abap.dats ) ) as NumberOfDays,
  likp.vsart                                                                 as ShippingType,
  vbbe.matnr                                                                 as Material,
  vbbe.werks                                                                 as Plant,
  lips.matkl                                                                 as MaterialGroup,
  marc.MaterialType,
  marc.CrossPlantConfigurableProduct,
  lips.sgt_rcat                                                              as RequirementSegment,
  likp.vbtyp                                                                 as SDDocumentCategory,
  likp.lfart                                                                 as DeliveryDocumentType,
  likp.vkorg                                                                 as SalesOrganization,
  lips.vtweg                                                                 as DistributionChannel,
  lips.spart                                                                 as Division,
  likp.bzirk                                                                 as SalesDistrict,
  likp.kunag                                                                 as SoldToParty,
  vbbe.lgort                                                                 as StorageLocation,
  vbbe.vbele                                                                 as SalesDocument,
  vbbe.posne                                                                 as SalesDocumentItem,
  case
    when marc.IsInternalBatchManaged = '1'
    then vbbe.charg
    else ''
  end                                                                        as Batch,
  vbbe.sobkz                                                                 as InventorySpecialStockType,
  lips.fsh_rsnum                                                             as Reservation,
  lips.fsh_rspos                                                             as ReservationItem,
  kna1.cvp_xblck                                                             as IsBusinessPurposeCompleted,
  lips.netpr                                                                 as NetPriceAmount,
  likp.waerk                                                                 as DocumentCurrency,
  vgbel                                                                      as ReferenceSDDocument,
  vgpos                                                                      as ReferenceSDDocumentItem,
  vgtyp                                                                      as ReferenceSDDocumentCategory
}
where
      vbbe.vbtyp = 'J' -- Delivery
  and vbbe.omeng > 0

Learn More