I_StatisticalKeyFigure

@ObjectModel.representativeKey: 'StatisticalKeyFigure' //Inserted by VDM CDS Suite Plugin

@EndUserText.label: 'Statistical Key Figure'
@AbapCatalog.sqlViewName: 'IFISTSTCKEYFIG'
@VDM.viewType: #BASIC
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
@AbapCatalog.buffering: {type: #GENERIC, numberOfKeyFields: 1, status: #ACTIVE}
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.compiler.compareFilter: true
@Metadata.allowExtensions: true
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET]
define view I_StatisticalKeyFigure as select from tka03 
association [0..*] to I_StatisticalKeyFigureText as _Text 
   on $projection.ControllingArea       = _Text.ControllingArea 
  and $projection.StatisticalKeyFigure  = _Text.StatisticalKeyFigure
  
association[0..1] to I_ControllingArea as _ControllingArea 
   on $projection.ControllingArea = _ControllingArea.ControllingArea
   
association [0..1] to I_StatisticalKeyFigureCat as _StatisticalKeyFigureCat
  on  $projection.StstcKeyFigCategory  = _StatisticalKeyFigureCat.StstcKeyFigCategory

association [0..1] to I_UnitOfMeasure as _UnitOfMeasure
  on  $projection.StstcKeyFigQuantityUnit      = _UnitOfMeasure.UnitOfMeasure

association [0..*] to I_StstclKeyFigureHierNode  as _StstclKeyFigureHierNode on $projection.ControllingArea = _StstclKeyFigureHierNode.ControllingArea
                                                                            and $projection.StatisticalKeyFigure = _StstclKeyFigureHierNode.StatisticalKeyFigure 

{
@ObjectModel.hierarchy.association: '_StstclKeyFigureHierNode'
@ObjectModel.text.association: '_Text'
    key cast(stagr as fis_stagr) as StatisticalKeyFigure,
@ObjectModel.foreignKey.association: '_ControllingArea' //Inserted by VDM CDS Suite Plugin

    key cast(kokrs as fis_kokrs) as ControllingArea,
@ObjectModel.foreignKey.association: '_UnitOfMeasure'
    msehi as StstcKeyFigQuantityUnit,
@ObjectModel.foreignKey.association: '_StatisticalKeyFigureCat'
    grtyp as StstcKeyFigCategory,
    
    hktyp   as StstclKeyFigureOrigin,
    
    struct  as LogsInformationSystemTable,
    
    kennz   as LogsInfoSystemKeyFigure,
    
    w_flag  as StstclKeyFigureIsCurrency,
     
    m_plan  as StstclKeyFigProcgPlndValType,
    
    m_ist   as StstclKeyFigProcgActlValType,
        
    _Text,
    _ControllingArea,
    _StatisticalKeyFigureCat,
    _UnitOfMeasure,
    _StstclKeyFigureHierNode
}