I_SrvcTransOneOrderField

@AbapCatalog.sqlViewName: 'IONEORDMP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'One order field mapping'
@ClientHandling.algorithm:#SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
   usageType: {
     dataClass:      #CUSTOMIZING,
     serviceQuality: #C,
     sizeCategory:   #M
   }
}

define view I_SrvcTransOneOrderField
  as select from            crms4s_1o_api_mp           as mp
    left outer to many join I_SrvcTransOneOrderFldDetn as am on mp.interface_field = am.BusSolutionQuotationProperty
    inner join              dd03nd                     as tf on tf.fieldname   = mp.interface_field
                                                             and(
                                                               tf.strucobjn    = 'A_BUSSOLNQTANSUBSCRPNITEM'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITMPRICEELEMENT'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMTEXT'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMTECHRSCE'
                                                               or tf.strucobjn = 'A_BUSOQTANITMFUPSUBSCRPNCONTR'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMDTEPARAM'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMSTRPARAM'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMNMRCPARAM'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITEMTBLPARAM'
                                                               or tf.strucobjn = 'A_BUSSOLNQTANITMCONFIGN'
                                                             )
{
  key interface_field  as BusSolutionQuotationProperty,
  key am.SrvcTransacOneOrdDetnIdfr,
  key tf.strucobjn as CDSView,
      oneord_fieldname as SrvcTransactionOneOrderField,
      oneord_bt_subobj as SrvcTransOneOrderSubObj,
      am.SrvcTransacOneOrdDetermination

}