I_SetHeader

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISETHEADER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Set Header'

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@ObjectModel.representativeKey: 'SetID'

define view I_SetHeader
  as select from setheader

  association [0..1] to I_SetClass      as _SetClass    on  $projection.SetClass = _SetClass.SetClass

  association [0..1] to I_SetSubClass   as _SetSubClass on  $projection.SetSubClass = _SetSubClass.SetSubClass

  association [0..*] to I_SetHeaderText as _SetHeaderText on  $projection.SetClass    = _SetHeaderText.SetClass
                                                          and $projection.SetSubClass = _SetHeaderText.SetSubClass
                                                          and $projection.SetID       = _SetHeaderText.SetID

{

      @ObjectModel.foreignKey.association:'_SetClass'
  key setheader.setclass   as SetClass,
      @ObjectModel.foreignKey.association:'_SetSubClass'
  key setheader.subclass   as SetSubClass,
      @ObjectModel.text.association: '_SetHeaderText'
  key setheader.setname    as SetID,
      setheader.settype    as SetType,
      setheader.xdynamic   as IsDynamic,
      //setheader.authgr    as AuthorizationGroup,

      setheader.xuniq      as IsUnique,
      setheader.rvalue     as SetRepresentativeValue,
      setheader.creuser    as CreatedByUser,
      setheader.credate    as CreationDate,
      setheader.cretime    as CreationTime,
      setheader.upduser    as LastChangedByUser,
      setheader.upddate    as LastChangedDate,
      setheader.updtime    as LastChangeTime,

      setheader.tabname    as DatabaseTable,
      setheader.fieldname  as DatabaseTableField,
      setheader.rollname   as SetRepresentativeDataElement,
      setheader.set_olangu as MasterLanguage,


      _SetClass,
      _SetSubClass,
      //_AuthorizationGroup ,

      _SetHeaderText

}