I_ServiceOrderItemEnhcd

@AbapCatalog.sqlViewName: 'ISERVORDITMENHCD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl :{
    authorizationCheck: #CHECK,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Get basic data for Service Order Item'
@Search.searchable: true
@VDM: {
  viewType: #COMPOSITE
}
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   representativeKey: 'ServiceDocumentItem',
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
//Selecting from I_ServiceDocumentEnhcd seince we need to consider the confirmations with out Item.

//Item is exposed from order view.

define view I_ServiceOrderItemEnhcd
  as select from I_ServiceDocumentEnhcd
    inner join   P_SrvcOrderSrvcConfInfo as _ServiceOrder on  I_ServiceDocumentEnhcd.ServiceDocument   = _ServiceOrder.ServiceDocument
                                                          and I_ServiceDocumentEnhcd.ServiceObjectType = _ServiceOrder.ServiceObjectType

  association [1..*] to I_CustomerSEPAMandate as _CustomerSEPAMandate on  $projection.SEPAMandate                 = _CustomerSEPAMandate.SEPAMandate
                                                                      and _CustomerSEPAMandate.SEPAMandateVersion = '0000'
  // association [1..1] to I_SEPAMandateStatus            as _SEPAMandateStatus           on  $projection.sepamandatestatus = _SEPAMandateStatus.SEPAMandateStatus

  association [0..1] to I_WBSElementBasicData as _WBSElement          on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID



{
          @Search.defaultSearchElement: true
  key     I_ServiceDocumentEnhcd.ServiceDocument,
  key     _ServiceDocItem.ServiceDocumentItem,
          _ServiceOrder.ServiceOrder                                          as ServiceOrder,
          I_ServiceDocumentEnhcd.ServiceObjectType,
          ServiceDocumentDescription,
          _ServiceDocItem.PurchaseOrderByCustomer                             as PurchaseOrderByCustomer,
          _ServiceDocItem.ServiceDocumentItemStatus                           as ServiceDocumentItemStatus,
          ServiceDocumentUUID,
          case _ServiceDocItem.ServiceDocumentItemStatus
          when 'A' then 0
          when 'B' then 0
          when 'C' then 3
          when 'D' then 3
          end                                                                 as ServiceConfErrorStsCriticality,
          //Incident 1970522238: change in case evaluation

          case _ServiceDocItem.ServiceDocItemBillingStatus
          when ' ' then 0
          when 'A' then 1
          when 'B' then 2
          when 'C' then 3
          end                                                                 as ServiceDocIsRelForBillCritlty,

          case  ServiceDocumentStatus
          when 'A' then 0
          when 'B' then 1
          when 'C' then 3
          when 'D' then 2
          end                                                                 as SrvcDocOvrlBillgBlkStsCritlty,

          _ServiceDocItem.ServiceDocItemBillingStatus                         as ServiceDocItemBillingStatus,

          _ServiceDocItem.PaymentTerms                                        as PaymentTerms,

          _ServiceDocItem.SrvcSEPAMandateRelevance,


          _ServiceDocItem.SEPAMandate                                         as SEPAMandate,

          // _CustomerSEPAMandatem.SEPAMandateCreditor                                                                                   as SEPAMandateCreditor,


          //_ServiceDocItem._CustomerSEPAMandate.SEPAMandateApplication                                                                                as SEPAMandateApplication,


          //_ServiceDocItem._CustomerSEPAMandate.SEPAMandateStatus                                                                                     as SEPAMandateStatus,


          _ServiceDocItem.SrvcDocItemExecutionStatus                          as SrvcOrdItemExecutionStatus,

          _ServiceDocItem.WBSElementInternalID                                as WBSElementInternalID,

          ServiceDocumentRejectionReason,


          case _ServiceDocItem.ServiceDocumentItemIsRejected
                     when 'X'then cast( 'X' as crmt_boolean )
                     when ' ' then cast( '' as crmt_boolean )
                     end                                                      as ServiceDocumentItemIsRejected,

          ServiceDocumentIsRejected                                           as ServiceDocumentIsRejected,

          // Baseline Cost Posting Status

          _ServiceDocItem.SrvcDocItmBslnCostPostgStatus,
          // Continuous Cost Calculation Status

          _ServiceDocItem.SrvcDocItmContinuousCostStatus,

          _ServiceDocItem.BillableControl                                     as BillableControl,
          _ServiceDocItem.ControllingArea                                     as ControllingArea,
          _ServiceDocItem.BillingPriceSourceName                              as BillingPriceSourceName,
          _ServiceDocItem.DocumentDescription                                 as DocumentDescription,
          _ServiceDocItem.TimeSheetOvertimeCategory                           as TimeSheetOvertimeCategory,
          _ServiceDocItem.ServiceDocumentItemUUID,
          @Semantics.uuid:true
          _ServiceDocItem.ServiceDocumentItemCharUUID,
          _ServiceDocItem.ServiceDocumentItemDescription                      as ServiceDocumentItemDescription,
          _ServiceDocItem.OriginallyRequestedProduct                          as OriginallyRequestedProduct,
          _ServiceDocItem.ServiceDocItemQuantityUnit                          as ServiceDocItemQuantityUnit,
          _ServiceDocItem.ServiceDocItemGrossAmount                           as ServiceDocItemGrossAmount,
          _ServiceDocItem.ServiceDocumentItemQuantity                         as ServiceDocumentItemQuantity,
          _ServiceDocItem.TransactionCurrency                                 as TransactionCurrency,
          _ServiceDocItem.ActualServiceDuration                               as ActualServiceDuration,
          _ServiceDocItem.ActualServiceDurationUnit                           as ActualServiceDurationUnit,
          _ServiceDocItem.ServiceDuration                                     as ServiceDuration,
          _ServiceDocItem.ServiceDurationUnit                                 as ServiceDurationUnit,
          _ServiceDocItem.CumulativeConfirmedQuantity                         as SrvcOrdItemReservedQuantity,
          case _ServiceDocItem.ServiceDocumentItemStatus
                   when 'A' then 0
                   when 'B' then 1
                   when 'C' then 3
                   when 'D' then 2
                   end                                                        as ServiceOrdErrorStsCriticality,
          _ServiceDocItem.ServiceDocumentItemObjectType                       as ServiceDocumentItemObjectType,
          _ServiceDocItem.PlannedServiceStartDateTime                         as PlannedServiceStartDateTime,
          _ServiceDocItem.PlannedServiceEndDateTime                           as PlannedServiceEndDateTime,
          _ServiceDocItem.ParentServiceDocumentItemUUID                       as ParentServiceDocumentItemUUID,
          _ServiceDocItem.ServiceDocumentItemPriority                         as ServiceDocumentItemPriority,
          _ServiceDocItem.ContactPerson                                       as ContactPerson,
          I_ServiceDocumentEnhcd.ServiceDocumentType                          as ServiceDocumentType,
          _ServiceDocItem.PostingDate                                         as PostingDate,
          _ServiceDocItem.SoldToPartyCountry                                  as SoldToPartyCountry,
          _ServiceDocItem.SoldToPartyRegion                                   as SoldToPartyRegion,
          _ServiceDocItem.ServiceDocumentItemIsOpen                           as ServiceDocumentItemIsOpen,
          _ServiceDocItem.ServiceDocumentItemIsReleased                       as ServiceDocumentItemIsReleased,
          _ServiceDocItem.ServiceDocumentItemIsQuotation                      as ServiceDocumentItemIsQuotation,
          _ServiceDocItem.SrvcDocItemTransferStatus                           as SrvcDocItemTransferStatus,
          _ServiceDocItem.ServiceTeam                                         as ServiceTeam,
          _ServiceDocItem.SoldToParty                                         as SoldToParty,
          _ServiceDocItem.ServiceEmployee                                     as ServiceEmployee,
          _ServiceDocItem.ResponsibleEmployee                                 as ResponsibleEmployee,
          _ServiceDocItem.ServiceDocumentItemHasError                         as ServiceDocumentItemHasError,
          case _ServiceDocItem.ServiceDocumentItemHasError
                      when 'X' then 1
                      when ' ' then 0
                      else 3
                    end                                                       as Criticality,
          case ServiceDocumentHasError
            when 'X' then 1
            when ' ' then 0
            else 3
          end                                                                 as SrvcDocMsgCriticality,
          ServiceDocumentHasError,
          ServiceDocumentStatus,
          _ServiceDocItem.ActualServiceStartDateTime,
          _ServiceDocItem.BillingDateTime,
          _ServiceDocItem.ProfitCenterDeterminationDate                       as ProfitCenterDeterminationDate,
          _ServiceDocItem.RequestedServiceStartDateTime,
          _ServiceDocItem.RequestedServiceEndDateTime,
          _ServiceDocItem.ServicesRenderedDate,
          //_ServiceDocItem.RequestedServiceStartDate,

          @Semantics.uuid:true
          ServiceDocumentCharUUID,
          _ServiceDocItem.ServiceDocItemCategory                              as ServiceDocItemCategory,
          _ServiceDocItem.ProfitCenter                                        as ProfitCenter,
          _ServiceDocItem.SrvcDocItmIsReleasedForBilling                      as SrvcDocItmIsReleasedForBilling,
          _ServiceDocItem.ServiceOrganization                                 as ServiceOrganization,
          _ServiceDocItem.ResponsibleServiceOrganization                      as ResponsibleServiceOrganization,
          _ServiceDocItem.ServiceDocItemCreationDateTime                      as ServiceDocItemCreationDateTime,
          _ServiceDocItem.ServiceDocItemChangedDateTime                       as ServiceDocItemChangedDateTime,
          _ServiceDocItem.ServiceDocItemCreatedByUser                         as ServiceDocItemCreatedByUser,
          _ServiceDocItem.ServiceDocItemChangedByUser                         as ServiceDocItemChangedByUser,
          _ServiceDocItem.PayerParty                                          as PayerParty,
          _ServiceDocItem.ShipToParty                                         as ShipToParty,
          _ServiceDocItem.BillToParty                                         as BillToParty,
          _ServiceDocItem.ServiceDocItemRejectionReason,
          _ServiceDocItem.SalesOrganization,
          _ServiceDocItem.PaymentMethod,
          _ServiceDocItem._PaymentMethod.PaymentMethodDescription,
          _ServiceDocItem.DistributionChannel,
          _ServiceDocItem.Division,
          _ServiceDocItem.SalesOffice,
          _ServiceDocItem.SalesGroup,
          _ServiceDocItem.SalesOrganizationOrgUnitID,
          _ServiceDocItem.SalesOfficeOrgUnitID,
          _ServiceDocItem.SalesGroupOrgUnitID,
          _ServiceDocItem._ServiceTeamHeader.TeamName                         as RespyMgmtServiceTeamName,
          _ServiceDocItem._ServiceTeamHeader._TeamDescription.TeamDescription as RespyMgmtServiceTeamDesc,
          _ServiceDocItem.ServiceProfile,
          _ServiceDocItem.ResponseProfile,
          _ServiceDocItem.ServiceFirstResponseByDateTime,
          _ServiceDocItem.SrvcDocItemSLADueByDateTime,
          _ServiceDocItem.SrvcDocItemCreditStatus                             as SrvcOrdItemCreditStatus,
          _ServiceDocItem.SrvcDocItemIsUnplanned                              as SrvcOrdItemIsUnplanned,
          // Net Value

          _ServiceDocItem.ServiceDocumentItemNetAmount,
          // Billing Relevant

          _ServiceDocItem._ServiceDocItemCategory.ItemIsBillingRelevant,
          _ServiceDocItem._ContactPerson,
          _ServiceDocItem._RespEmployee,
          _ServiceDocItem._ServiceDocItemBillingStatus,
          _ServiceDocItem._ServiceDocItemCategory,
          _ServiceDocItem._ServiceDocItemHasError,
          _ServiceDocItem._ServiceDocItemPriority,
          _ServiceDocItem._ServiceDocItemStatus,
          _ServiceDocItem._SrvcDocItemTransferStatus,
          I_ServiceDocumentEnhcd._ServiceDocumentType,
          _ServiceDocItem._ServiceEmployee,
          _ServiceDocItem._ServiceTeam,
          _ServiceDocItem._SoldToParty,
          _ServiceDocItem._SrvcDocItemIsRelForBillgSts,
          _ServiceDocItem._PayerParty,
          _ServiceDocItem._ShipToParty,
          _ServiceDocItem._BillToParty,
          _ServiceDocItem._ResponseProfile,
          _ServiceDocItem._ServiceProfile,
          _ServiceDocItem._ServiceDocOvertimeCat,
          _ServiceDocItem._ServiceDocItmPrdcssr_2,
          _ServiceDocItem._SalesOrganization,
          _ServiceDocItem._SalesOffice,
          _ServiceDocItem._SalesGroup,
          _ServiceDocItem._Division,
          _ServiceDocItem._DistributionChannel,
          _ServiceDocItem._PaymentTerms,
          _ServiceDocItem._PaymentMethod,
          _ServiceDocItem._SrvcSEPAMandateRelevance,
          _ServiceDocItem._ProfitCenter,
          _ServiceDocItem._SrvcDocItemCreditStatus,
          // Baseline Cost Posting Status

          _ServiceDocItem._SrvcDocItmBslnCostPostgStat,
          // Continuous Cost Calculation Status

          _ServiceDocItem._SrvcDocItmContinuousCostStat,
          //_ServiceDocItem._ServiceDocItemNote,

          //_ServiceTeamHeader,

          _ServiceDocItem,
          _ServiceDocumentStatus,
          _ServiceDocPredecessor,
          _ServiceDocSuccessor,
          _ServiceDocHasError,
          _SrvcDocumentRejectionReason,
          _ServiceDocItem._SrvcDocExecutionStatus,
          _CustomerSEPAMandate,
          _WBSElement

          //          @UI.lineItem.hidden: true

          //          _SrvcOrderListRptAndObjPg._ServiceDocumentStatus

}
where
       ServiceDocumentIsQuotation               = ''
  and(
       I_ServiceDocumentEnhcd.ServiceObjectType = 'BUS2000116'
    or I_ServiceDocumentEnhcd.ServiceObjectType = 'BUS2000117'
  )