I_ServiceContractStdVH

DDL: I_SERVICECONTRACTSTDVH SQL: ISERVCONTRVH Type: view COMPOSITE

Service Contract Value Help

I_ServiceContractStdVH is a Composite CDS View that provides data about "Service Contract Value Help" in SAP S/4HANA. It reads from 1 data source (I_ServiceDocument) and exposes 30 fields with key fields ServiceDocumentType, ServiceDocument.

1 data source(s) 30 fields

Data Sources (1)

SourceAliasJoin Type
I_ServiceDocument I_ServiceDocument from

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName ISERVCONTRVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey ServiceDocument view
VDM.viewType #COMPOSITE view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Service Contract Value Help view
Search.searchable true view
Consumption.ranked true view

Fields (30)

KeyFieldSource TableSource FieldDescription
KEY ServiceDocumentType ServiceDocumentType
KEY ServiceDocument ServiceDocument
ServiceObjectType ServiceObjectType
ServiceDocumentDescription ServiceDocumentDescription
SalesOrganization SalesOrganization
DistributionChannel DistributionChannel
Division Division
SalesOffice SalesOffice
SalesGroup SalesGroup
_ServiceDocumentType _ServiceDocumentType
SalesOrganizationOrgUnitID SalesOrganizationOrgUnitID
SalesOfficeOrgUnitID SalesOfficeOrgUnitID
SalesGroupOrgUnitID SalesGroupOrgUnitID
ServiceOrganization ServiceOrganization
ResponsibleEmployee ResponsibleEmployee
_ServiceObjType _ServiceObjType
_SalesOrganization _SalesOrganization
_DistributionChannel _DistributionChannel
_Division _Division
_SalesOffice _SalesOffice
_SalesGroup _SalesGroup
_SalesOrganizationOrgUnit _SalesOrganizationOrgUnit
_SalesOrganizationOrgUnit_2 _SalesOrganizationOrgUnit_2
_SalesOfficeOrgUnit _SalesOfficeOrgUnit
_SalesOfficeOrgUnit_2 _SalesOfficeOrgUnit_2
_SalesGroupOrgUnit _SalesGroupOrgUnit
_SalesGroupOrgUnit_2 _SalesGroupOrgUnit_2
_ServiceOrganizationOrgUnit _ServiceOrganizationOrgUnit
_ServiceOrganizationOrgUnit_2 _ServiceOrganizationOrgUnit_2
_RespEmployee _RespEmployee 
@AbapCatalog.sqlViewName: 'ISERVCONTRVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ServiceDocument'
@VDM.viewType: #COMPOSITE
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL }
@ObjectModel.supportedCapabilities: [ #VALUE_HELP_PROVIDER ]
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Service Contract Value Help'
@Search: {
  searchable: true
}
@Consumption.ranked:true

define view I_ServiceContractStdVH
  as select from I_ServiceDocument
{
      
      @Search.ranking: #LOW
  key ServiceDocumentType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key ServiceDocument,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ServiceDocumentDescription,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      
      _ServiceDocumentType,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,
      
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      
      @Search.ranking: #LOW
      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,
      
      @Search.ranking: #LOW
      @UI.hidden: true
      @Consumption.filter.hidden: true 
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee,
      
      
      //Association

      _ServiceObjType,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOrganizationOrgUnit_2'
      _SalesOrganizationOrgUnit,
      _SalesOrganizationOrgUnit_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOfficeOrgUnit_2'
      _SalesOfficeOrgUnit,
      _SalesOfficeOrgUnit_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesGroupOrgUnit_2'       
      _SalesGroupOrgUnit,
      _SalesGroupOrgUnit_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_ServiceOrganizationOrgUnit_2'  
      _ServiceOrganizationOrgUnit,
      _ServiceOrganizationOrgUnit_2,
      _RespEmployee
      
}
where
  ServiceObjectType = 'BUS2000112'
  and ServiceDocumentTemplateType = ''

Learn More