I_SecurityClassLstdDerivative

// harmonized annotations 

@AbapCatalog.buffering.status: #NOT_ALLOWED 
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true // only if required by ATC check 

@AbapCatalog.sqlViewName: 'ISECLSTDDRVTV' 
@AccessControl.authorizationCheck: #CHECK // according to XLS / DCL 

@Analytics.dataCategory: #DIMENSION 
@Analytics.dataExtraction.enabled: true // use only if view is customizing or small master data 

@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Security Class Listed Derivative'
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'SecurityClass'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L 
@Metadata.allowExtensions:true 
@Metadata.ignorePropagatedAnnotations: true // For C1-Release   

@VDM.viewType: #BASIC

define view I_SecurityClassLstdDerivative
  as select from vtideri
  
  association [0..1] to I_SecurityClass as _SecurityClass on $projection.SecurityClass = _SecurityClass.SecurityClass  
  association [0..1] to I_ListedDerivativeQuotation as _ListedDerivativeQuotation on $projection.ListedDerivativeQuotation = _ListedDerivativeQuotation.ListedDerivativeQuotation

  association [0..1] to I_ListedDerivativeCategory  as _ListedDerivativeCategory  on $projection.ListedDerivativeCategory = _ListedDerivativeCategory.ListedDerivativeCategory
  association [0..1] to I_OptionPutCallCode         as _OptionPutCallCode         on $projection.OptionPutCallCode = _OptionPutCallCode.OptionPutCallCode

{
  key cast(ranl as ftr_gen_security_class preserving type)              as SecurityClass,
      cast(snottype as ftr_gen_listed_deriv_quotation preserving type ) as ListedDerivativeQuotation,
      softyp                                                            as ListedDerivativeCategory,
      sputcall                                                          as OptionPutCallCode,
      sgsart                                                            as FinancialInstrumentProductType,
      cast(debeg as ftr_gen_first_quotation_date preserving type )      as LstdDerivative1stQuotationDate,
      cast(dlhandel as ftr_gen_last_quotation_date preserving type )    as LstdDerivativeLastQuotationDte,
      derfuell                                                          as ListedDerivativeSettlementDate,
      cast(dverfall as delfz preserving type )                          as ListedDerivativeTermEndDate,
     
      _SecurityClass,
      _ListedDerivativeQuotation, // Make association public

      _ListedDerivativeCategory,
      _OptionPutCallCode
}