I_ScheduleLineConfStatusText

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'ScheduleLineConfirmationStatus'
@ObjectModel.usageType.dataClass: #META 
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #S 
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, 
                                      #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.modelingPattern: [ #LANGUAGE_DEPENDENT_TEXT ] 
@EndUserText.label: 'Confirmation Status of Schedule Line - Text'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:  #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDSCHDLCONFSTST'
@Metadata.ignorePropagatedAnnotations:true
@Search.searchable: true

define view I_ScheduleLineConfStatusText
as select from dd07t 

association[0..1] to I_ScheduleLineConfStatus as _ScheduleLineConfStatus on $projection.ScheduleLineConfirmationStatus = _ScheduleLineConfStatus.ScheduleLineConfirmationStatus
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_ScheduleLineConfStatus'
    key SUBSTRING(domvalue_l, 1, 1) as ScheduleLineConfirmationStatus,

    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    key ddlanguage as Language,

    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.9
    ddtext as ScheduleLineConfStatusDesc,
    
    //Associations

    _ScheduleLineConfStatus,
    _Language
}
where (dd07t.domname = 'ECOST') and (dd07t.as4local = 'A');