I_SalesOperationsPlanningOrder

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_MRPController']
@Analytics.dataCategory: #DIMENSION
@Analytics.technicalName: 'IPPSOPORDER'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'SalesOperationsPlanningOrder'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #M, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Sales Operations Planning Order'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_SalesOperationsPlanningOrder
  as select from sauf as sauf

  association [1..1] to I_Material                as _Material                on  $projection.Material = _Material.Material
  association [1..1] to I_Plant                   as _Plant                   on  $projection.Plant = _Plant.Plant
  association [1..1] to I_MaterialPlant           as _MaterialPlant           on  $projection.Plant    = _MaterialPlant.Plant
                                                                              and $projection.Material = _MaterialPlant.Material
  association [0..1] to I_MRPController           as _MRPController           on  $projection.Plant         = _MRPController.Plant
                                                                              and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_ResponsiblePlannerGroup as _ResponsiblePlannerGroup on  $projection.Plant                   = _ResponsiblePlannerGroup.Plant
                                                                              and $projection.ResponsiblePlannerGroup = _ResponsiblePlannerGroup.ResponsiblePlannerGroup
  association [0..1] to I_ProductionVersion       as _ProductionVersion       on  $projection.Material          = _ProductionVersion.Material
                                                                              and $projection.Plant             = _ProductionVersion.Plant
                                                                              and $projection.ProductionVersion = _ProductionVersion.ProductionVersion
  association [0..1] to I_FiscalYearVariant       as _FiscalYearVariant       on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
  association [0..1] to I_PeriodType              as _PeriodType              on  $projection.PeriodType = _PeriodType.PeriodType
  association [0..1] to I_SchedulingFloatProfile  as _SchedulingFloatProfile  on  $projection.Plant                  = _SchedulingFloatProfile.Plant
                                                                              and $projection.SchedulingFloatProfile = _SchedulingFloatProfile.SchedulingFloatProfile
  association [1..1] to I_UnitOfMeasure           as _BaseUnit                on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
{
      // Key

  key sauf.safnr  as SalesOperationsPlanningOrder,

      // Assignments

      @ObjectModel.foreignKey.association: '_Material'
      sauf.matnr  as Material,
      @ObjectModel.foreignKey.association: '_Plant'
      sauf.werks  as Plant,
      @ObjectModel.foreignKey.association: '_MRPController'
      cast(sauf.dispo as pph_dispo preserving type) as MRPController,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      cast(sauf.vagrp as vagrp     preserving type) as ResponsiblePlannerGroup,
      @ObjectModel.foreignKey.association: '_ProductionVersion'
      sauf.vsnda  as ProductionVersion,
      @ObjectModel.foreignKey.association: '_FiscalYearVariant'
      @Semantics.fiscal.yearVariant: true
      sauf.periv  as FiscalYearVariant,
      @ObjectModel.foreignKey.association: '_SchedulingFloatProfile'
      sauf.fhori  as SchedulingFloatProfile,
      @ObjectModel.foreignKey.association: '_PeriodType'
      sauf.perkz  as PeriodType,
      sauf.vrsio  as PlanningVersion,

      // Dates

      @Semantics.businessDate.from
      sauf.vondat as ValidityStartDate,
      @Semantics.businessDate.to
      sauf.bisdat as ValidityEndDate,

      // Quantities and UoM

      sauf.meins  as BaseUnit,

      // Associations

      _Material,
      _Plant,
      _MaterialPlant,
      _MRPController,
      _ResponsiblePlannerGroup,
      _ProductionVersion,
      _FiscalYearVariant,
      _SchedulingFloatProfile,
      _PeriodType,
      _BaseUnit
};