I_SESAccountAssignmentTP

@AbapCatalog.sqlViewName: 'ISRVCENTRSH001TP'
@EndUserText.label: 'Service Entry Sheet Account Assignment'
@ObjectModel.writeDraftPersistence: 'SRVCENTRSHTACC_D'
@ObjectModel.writeActivePersistence: 'ISRVCENTRSH001TP'
@VDM.viewType: #TRANSACTIONAL
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.updateEnabled: true
@ObjectModel.createEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: ['ServiceEntrySheet', 'ServiceEntrySheetItem', 'AccountAssignment']
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.sapObjectNodeType.name: 'ServiceEntrySheet'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_SESAccountAssignmentTP
  as select from I_ServiceEntrySheetAcctAssgmt as Document

  association [1..1] to I_ServiceEntrySheetTP     as _ServiceEntrySheet     on  _ServiceEntrySheet.ServiceEntrySheet = $projection.ServiceEntrySheet
  association [1..1] to I_ServiceEntrySheetItemTP as _ServiceEntrySheetItem on  _ServiceEntrySheetItem.ServiceEntrySheet     = $projection.ServiceEntrySheet
                                                                            and _ServiceEntrySheetItem.ServiceEntrySheetItem = $projection.ServiceEntrySheetItem

  association [0..1] to I_UnitOfMeasure           as _UnitValueHelp         on  _UnitValueHelp.UnitOfMeasure = $projection.QuantityUnit
  association [0..*] to I_UnitOfMeasureText       as _UnitText              on  _UnitText.UnitOfMeasure = $projection.QuantityUnit
  association [0..1] to I_ControllingArea         as _ControllingArea       on  _ControllingArea.ControllingArea = $projection.ControllingArea
  association [0..1] to I_GLAccount               as _GLAccount             on  _GLAccount.CompanyCode = $projection.CompanyCode
                                                                            and _GLAccount.GLAccount   = $projection.GLAccount
  association [0..*] to I_GLAccountText           as _GLAccountText         on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
                                                                            and $projection.GLAccount       = _GLAccountText.GLAccount
  association [0..1] to I_BusinessArea            as _BusinessArea          on  _BusinessArea.BusinessArea = $projection.BusinessArea
  association [0..*] to I_BusinessAreaText        as _BusinessAreaText      on  _BusinessAreaText.BusinessArea = $projection.BusinessArea
  association [0..1] to I_Currency                as _Currency              on  $projection.Currency = _Currency.Currency
{
      //      @ObjectModel.readOnly: true

  key Document.ServiceEntrySheet,
      //      @ObjectModel.readOnly: true

  key Document.ServiceEntrySheetItem,
  key Document.AccountAssignment,

      @ObjectModel.readOnly: true
      Document.RefDocAccountAssignment,
      @ObjectModel.readOnly: true
      Document.IsDeleted,
      Document.QuantityUnit,
      Document.Quantity,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.MultipleAcctAssgmtDistrPercent,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GLAccount,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BusinessArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      //@ObjectModel.foreignKey.association: '_SalesOrder'

      cast(Document.SalesOrder as vdm_sales_order)                               as SalesOrder,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      //@ObjectModel.foreignKey.association: '_SalesOrderItem'

      cast(SalesOrderItem as sales_order_item)                                   as SalesOrderItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.SalesOrderScheduleLine,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.MasterFixedAsset,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FixedAsset,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ControllingArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostObject,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProfitabilitySegment,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProfitCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast( Document.WBSElementInternalID_2 as ps_psp_pnr preserving type )      as WBSElementInternalID, //with conv. exit

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProjectNetwork,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ProjectNetworkInternalID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.NetworkActivityInternalID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.NetworkActivity,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.RealEstateObject,

      // new with CE 1911

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.CostCtrActivityType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BusinessProcess,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.SettlementReferenceDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GoodsRecipientName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.UnloadingPointName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderInternalID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.OrderIntBillOfOperationsItem,

      // Public Sector Fields

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast( CommitmentItemShortID as fipos preserving type ) as CommitmentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FundsCenter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.Fund,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.FunctionalArea,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.EarmarkedFundsDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.EarmarkedFundsDocumentItem,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.BudgetPeriod,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.GrantID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      //      cast( '  ' as fm_measure ) as FundedProgram,

      Document.FundedProgram,

      // Service Order Fields

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocumentType,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocument,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ServiceDocumentItem,

      Document.CreationDateTime,
      cast(Document.CreatedByUser as mmpur_ses_createdbyuser preserving type )   as CreatedByUser,
      //      Document.CreatedByUser,

      Document.LastChangeDateTime,
      cast(Document.LastChangeUser as mmpur_ses_lastchangeuser preserving type ) as LastChangeUser,
      //      Document.LastChangeUser,


      Document.PurchasingOrganization,
      Document.PurchasingGroup,
      Document.Plant,
      Document.IsEndOfPurposeBlocked,

      Document.ValidityDate,
      @ObjectModel.readOnly: true
      @Semantics.currencyCode:true
      Document.Currency,
      @Semantics.amount.currencyCode: 'Currency'
      @Aggregation.default: #NONE
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.NetAmount,
      Document.CompanyCode,
      Document.ChartOfAccounts,


      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _ServiceEntrySheet,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _ServiceEntrySheetItem,

      _UnitValueHelp,
      _UnitText,
      _Currency
}
where
  Document.IsDeleted = ' '