I_SDDocumentProcessItemsFlowVH

@AbapCatalog.sqlViewName: 'ISDDOCITMFLOWVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Billing Docs Items with Delivery Items'

@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.dataCategory: #VALUE_HELP

@Consumption.ranked: true
@ObjectModel.representativeKey: 'BillingDocument' 
define view I_SDDocumentProcessItemsFlowVH
  as select from I_SDDocumentProcessFlow as DocumentFlow
    inner join   I_BillingDocument       as BillingDocument     on BillingDocument.BillingDocument = DocumentFlow.SubsequentDocument
    inner join   I_BillingDocumentItem   as BillingDocumentItem on  BillingDocumentItem.BillingDocument     = DocumentFlow.SubsequentDocument
                                                                and BillingDocumentItem.BillingDocumentItem = DocumentFlow.SubsequentDocumentItem

{

      //

      //      @Search.ranking: #MEDIUM

      //      @Search.defaultSearchElement: true

      //      @Search.fuzzinessThreshold: 0.9

      // key SubsequentDocument,


      @Search.ranking: #MEDIUM
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
  key DocumentFlow.PrecedingDocument,
      @UI.hidden: true
  key DocumentFlow.PrecedingDocumentItem,


      @UI.selectionField.position: 10
      @UI.lineItem.position: 10
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 1
  key BillingDocument.BillingDocument,

      @UI.selectionField.position: 11
      @UI.lineItem.position: 15
      @ObjectModel.text.element: ['BillingDocument']
  key BillingDocumentItem.BillingDocumentItem,


      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      BillingDocumentItemText,

      @UI.selectionField.position: 15
      @UI.lineItem.position: 15
      BillingDocument.CompanyCode,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 11
      @UI.lineItem.position: 11
      BillingDocument.BillingDocumentType,

      @Consumption.filter.hidden: true
      @UI.lineItem.position: 12
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      _BillingDocumentType._Text[1:Language = $session.system_language].BillingDocumentTypeName,

      @UI.selectionField.position: 40
      @UI.lineItem.position: 40
      BillingDocument.SoldToParty,

      @UI.selectionField.position: 50
      @UI.lineItem.position: 50
      BillingDocument._SoldToParty.CustomerName,

      @UI.selectionField.position: 55
      @UI.lineItem.position: 55
      BillingDocument.PayerParty,

      @UI.selectionField.position: 60
      @UI.lineItem.position: 60
      BillingDocument.BillingDocumentDate,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 70
      @UI.lineItem.position: 70
      BillingDocument.CreationDate,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 80
      @UI.lineItem.position: 80
      BillingDocument.SalesOrganization,


      @Consumption.filter.hidden: true
      @UI.hidden: true
      cast( BillingDocument.BillingDocument as fac_ddf_anchor_document ) as AnchorDocument,


      @ObjectModel.readOnly
      @UI.hidden: true
      BillingDocument._SoldToParty.AuthorizationGroup,

      @ObjectModel.readOnly
      @UI.hidden: true
      BillingDocument._SoldToParty.CustomerAccountGroup,

      @ObjectModel.readOnly
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      BillingDocument._SoldToParty.IsBusinessPurposeCompleted,

      _Item


}

where
      SubsequentDocumentCategory = 'M'
  and PrecedingDocumentCategory  = 'J'