I_SDDocumentProcessFlowVH

@AbapCatalog.sqlViewName: 'ISDDOCPROCFLOWVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Billing Document based on Delivery Doc'

@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.dataCategory: #VALUE_HELP

@Consumption.ranked: true
@ObjectModel.representativeKey: 'BillingDocument'
define view I_SDDocumentProcessFlowVH
  as select distinct from I_SDDocumentProcessFlow as DocumentFlow
    inner join   I_BillingDocument       as BillingDocument     on BillingDocument.BillingDocument = DocumentFlow.SubsequentDocument
    left outer to one join   I_SDDocumentMultiLevelProcFlow as SalesOrder  on DocumentFlow.SubsequentDocument = SalesOrder.SubsequentDocument 
                                                       and SalesOrder.SubsequentDocumentCategory = 'M'
                                                       and SalesOrder.PrecedingDocumentCategory = 'C'


    left outer to one join   I_SDDocumentMultiLevelProcFlow as Contract  on SalesOrder.PrecedingDocument = Contract.SubsequentDocument 
                                                       and Contract.SubsequentDocumentCategory = 'C'
                                                       and Contract.PrecedingDocumentCategory = 'G'

{

      //

      //      @Search.ranking: #MEDIUM

      //      @Search.defaultSearchElement: true

      //      @Search.fuzzinessThreshold: 0.9

      // key SubsequentDocument,


      @Search.ranking: #MEDIUM
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
  key DocumentFlow.PrecedingDocument,

      @UI.selectionField.position: 10
      @UI.lineItem.position: 10
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 1
  key BillingDocument.BillingDocument,
      
      @UI.selectionField.position: 90
      SalesOrder.PrecedingDocument as SalesOrder,
      
      @UI.selectionField.position: 100
      Contract.PrecedingDocument as RU_ContractDocument,

      @UI.selectionField.position: 15
      @UI.lineItem.position: 15
      BillingDocument.CompanyCode,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 11
      @UI.lineItem.position: 11
      BillingDocument.BillingDocumentType,

      @Consumption.filter.hidden: true
      @UI.lineItem.position: 12
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      _BillingDocumentType._Text[1:Language = $session.system_language].BillingDocumentTypeName,

      @UI.selectionField.position: 40
      @UI.lineItem.position: 40
      BillingDocument.SoldToParty,

      @UI.selectionField.position: 50
      @UI.lineItem.position: 50
      _SoldToParty.CustomerName,

      @UI.selectionField.position: 55
      @UI.lineItem.position: 55
      PayerParty,

      @UI.selectionField.position: 60
      @UI.lineItem.position: 60
      BillingDocumentDate,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 70
      @UI.lineItem.position: 70
      BillingDocument.CreationDate,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      @UI.selectionField.position: 80
      @UI.lineItem.position: 80
      BillingDocument.SalesOrganization,


      @Consumption.filter.hidden: true
      @UI.hidden: true
      cast( BillingDocument.BillingDocument as fac_ddf_anchor_document ) as AnchorDocument,


      @ObjectModel.readOnly
      @UI.hidden: true
      _SoldToParty.AuthorizationGroup,

      @ObjectModel.readOnly
      @UI.hidden: true
      _SoldToParty.CustomerAccountGroup,

      @ObjectModel.readOnly
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      _SoldToParty.IsBusinessPurposeCompleted,

      _Item


}

where
      DocumentFlow.SubsequentDocumentCategory = 'M'
  and DocumentFlow.PrecedingDocumentCategory  = 'J'