I_RoutingPRTMasterDataSrchMod

@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true 
@ObjectModel.representativeKey: 'ProductionResourceInternalID'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER}
@VDM.viewType: #BASIC
@EndUserText.label: 'Production Resource/Tool Master Data'
@Analytics.technicalName: 'IRTGPRTMSTRDATA'
define view entity I_RoutingPRTMasterDataSrchMod
  as select from crfh

  association [1..1] to I_ProductionResourceType      as _ProductionResourceType        on $projection.ProductionResourceType = _ProductionResourceType.ProductionResourceType
//  association [1..1] to I_ProdnRsceToolCategory       as _ProdnRsceToolCategory         on $projection.ProdnRsceToolCategory = _ProdnRsceToolCategory.ProdnRsceToolCategory

  association [1..1] to I_ProdnRsceToolGroup          as _ProdnRsceToolGroup1           on $projection.ProductionResourceToolGroup1 = _ProdnRsceToolGroup1.ProductionResourceToolGroup
  association [1..1] to I_ProdnRsceToolGroup          as _ProdnRsceToolGroup2           on $projection.ProductionResourceToolGroup2 = _ProdnRsceToolGroup2.ProductionResourceToolGroup
  association [1..1] to I_ProductionResourceUsage     as _ProductionResourceUsage       on $projection.ProductionResourceUsage = _ProductionResourceUsage.ProductionResourceUsage
  association [0..1] to I_ProdnRsceToolControlProfile as _ProdnRsceToolControlProfile   on $projection.ProdnRsceToolControlProfile = _ProdnRsceToolControlProfile.ProdnRsceToolControlProfile
  association [1..1] to I_ProdnRsceToolStandardText   as _ProdnRsceToolStandardText     on $projection.ProdnRsceToolStandardTextCode = _ProdnRsceToolStandardText.ProdnRsceToolStandardTextCode
  association [0..1] to I_ChangeMaster                as _ChangeMaster                  on $projection.ChangeNumber = _ChangeMaster.ChangeNumber

  association [1..1] to I_ProdnRsceToolQtyCalcFormula as _ProdnRsceToolTotQtyCalcFmla   on $projection.ProdnRsceToolTotQtyCalcFormula = _ProdnRsceToolTotQtyCalcFmla.ProdnRsceToolQtyCalcFormula
  association [1..1] to I_ProdnRsceToolQtyCalcFormula as _ProdnRsceToolUsageQtyCalcFmla on $projection.ProdnRsceToolUsageQtyCalcFmla = _ProdnRsceToolUsageQtyCalcFmla.ProdnRsceToolQtyCalcFormula

  association [1..1] to I_OperationDateOffsetRefCode  as _StartDateOffsetReferenceCode  on $projection.StartDateOffsetReferenceCode = _StartDateOffsetReferenceCode.OperationDateOffsetRefCode
  association [1..1] to I_OperationDateOffsetRefCode  as _EndDateOffsetReferenceCode    on $projection.EndDateOffsetReferenceCode = _EndDateOffsetReferenceCode.OperationDateOffsetRefCode

  association [0..1] to I_UnitOfMeasure               as _StartDateOffsetDurationUnit   on $projection.StartDateOffsetDurationUnit = _StartDateOffsetDurationUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _EndDateOffsetDurationUnit     on $projection.EndDateOffsetDurationUnit = _EndDateOffsetDurationUnit.UnitOfMeasure

  association [1..1] to I_User                        as _CreatedByUser                 on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser             on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_MaterialPRTByInternalKey    as _MaterialPRTByInternalKey      on $projection.ProductionResourceType = _MaterialPRTByInternalKey.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _MaterialPRTByInternalKey.ProductionResourceInternalID  
  association [0..1] to I_EquipmentPRTByInternalKey   as _EquipmentPRTByInternalKey     on $projection.ProductionResourceType = _EquipmentPRTByInternalKey.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _EquipmentPRTByInternalKey.ProductionResourceInternalID
  association [0..1] to I_DocumentPRTByInternalKey    as _DocumentPRTByInternalKey     on $projection.ProductionResourceType = _DocumentPRTByInternalKey.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _DocumentPRTByInternalKey.ProductionResourceInternalID
  association [0..1] to I_MiscPRTByInternalKey        as _MiscPRTByInternalKey         on $projection.ProductionResourceType = _MiscPRTByInternalKey.ProductionResourceType
                                                                                        and $projection.ProductionResourceInternalID = _MiscPRTByInternalKey.ProductionResourceInternalID
{
      @ObjectModel.foreignKey.association: '_ProductionResourceType'
  key cast(crfh.objty as productionresourcetype preserving type)        as ProductionResourceType,
      // Representative Key

  key cast(crfh.objid as pph_fhmid preserving type)                     as ProductionResourceInternalID,

      // Assignments

//      @ObjectModel.foreignKey.association: '_ProdnRsceToolCategory'

//      crfh.fhmar                                                        as ProdnRsceToolCategory,

      @ObjectModel.foreignKey.association: '_ProdnRsceToolGroup1'
      crfh.fgru1                                                        as ProductionResourceToolGroup1,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolGroup2'
      crfh.fgru2                                                        as ProductionResourceToolGroup2,
      @ObjectModel.foreignKey.association: '_ProductionResourceUsage'
      crfh.planv                                                        as ProductionResourceUsage,
      // Technical field, used for Miscellaneous Production Resource Tool only !

      crfh.brgru                                                        as MiscPRTAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolControlProfile'
      crfh.steuf                                                        as ProdnRsceToolControlProfile,
      @ObjectModel.foreignKey.association: '_ChangeMaster'
      cast(crfh.aennr as changenumber preserving type)                  as ChangeNumber,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolStandardText'
      crfh.ktsch                                                        as ProdnRsceToolStandardTextCode,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolTotQtyCalcFmla'
      crfh.mgform                                                       as ProdnRsceToolTotQtyCalcFormula,
      @ObjectModel.foreignKey.association: '_ProdnRsceToolUsageQtyCalcFmla'
      crfh.ewform                                                       as ProdnRsceToolUsageQtyCalcFmla,

      // Administrative Data

      @Semantics.systemDate.createdAt: true
      crfh.andat                                                        as CreationDate,
      @Semantics.user.createdBy: true
      cast(crfh.annam as vdm_createdbyuserid preserving type)           as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      crfh.aedat                                                        as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      crfh.aenam                                                        as LastChangedByUser,

      // Offset

      @ObjectModel.foreignKey.association: '_StartDateOffsetReferenceCode'
      cast(crfh.bzoffb as startdateoffsetreferencecode preserving type) as StartDateOffsetReferenceCode,
      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      cast(crfh.offstb as startdateoffsetduration preserving type)      as StartDateOffsetDuration,
//      @Semantics.unitOfMeasure: true

      crfh.ehoffb                                                       as StartDateOffsetDurationUnit,
      
      @ObjectModel.foreignKey.association: '_EndDateOffsetReferenceCode'
      cast(crfh.bzoffe as enddateoffsetreferencecode preserving type)   as EndDateOffsetReferenceCode,
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      cast(crfh.offste as enddateoffsetduration preserving type)        as EndDateOffsetDuration,
//      @Semantics.unitOfMeasure: true

      crfh.ehoffe                                                       as EndDateOffsetDurationUnit,

      // Associations

      _ProductionResourceType,
//      _ProdnRsceToolCategory,

      _ProdnRsceToolGroup1,
      _ProdnRsceToolGroup2,
      _ProductionResourceUsage,
      _ProdnRsceToolControlProfile,
      _ProdnRsceToolStandardText,
      _ProdnRsceToolTotQtyCalcFmla,
      _ProdnRsceToolUsageQtyCalcFmla,
      _StartDateOffsetReferenceCode,
      _EndDateOffsetReferenceCode,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,
      _CreatedByUser,
      _LastChangedByUser,
      _ChangeMaster,
      _MaterialPRTByInternalKey,
      _EquipmentPRTByInternalKey,
      _DocumentPRTByInternalKey,
      _MiscPRTByInternalKey
}
where
      crfh.objty = 'FH' // Production Resource Tool

  and crfh.zaehl = '00000000'      
  and crfh.loekz = ' '  // not deleted