I_RoutingCompAllocSrchMod

@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
//@Analytics.dataCategory: #DIMENSION

@ObjectModel.representativeKey: 'BOOOpBOMItemIntVersCounter'
@Analytics.technicalName: 'IRTGCMPALCSRHMOD'
@EndUserText.label: 'Bill of Operations Operation BOM Item'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Search.searchable: true
//@Metadata.allowExtensions:true

define view entity I_RoutingCompAllocSrchMod
  as select from plmz

  association [1..1] to I_BillOfOperationsType      as _BillOfOperationsType      on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup     as _BillOfOperationsGroup     on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  association [1..1] to I_BillOfOperations          as _BillOfOperations          on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..1] to I_BillOfOperationsSequence  as _BillOfOperationsSequence  on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                  and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence

  association [1..1] to I_BillOfOperationsOperation as _BillOfOperationsOperation on  $projection.BillOfOperationsType     = _BillOfOperationsOperation.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup    = _BillOfOperationsOperation.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant  = _BillOfOperationsOperation.BillOfOperationsVariant
                                                                                  and $projection.BillOfOperationsSequence = _BillOfOperationsOperation.BillOfOperationsSequence
                                                                                  and $projection.BOOOperationInternalID   = _BillOfOperationsOperation.BOOOperationInternalID

  association [1..1] to I_BOOOperationInternalID    as _BOOOperationInternalID    on  $projection.BillOfOperationsType   = _BOOOperationInternalID.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup  = _BOOOperationInternalID.BillOfOperationsGroup
                                                                                  and $projection.BOOOperationInternalID = _BOOOperationInternalID.BOOOperationInternalID

  association [1..1] to I_BOOOpBOMItemInternalID    as _BOOOpBOMItemInternalID    on  $projection.BillOfOperationsType     = _BOOOpBOMItemInternalID.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup    = _BOOOpBOMItemInternalID.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant  = _BOOOpBOMItemInternalID.BillOfOperationsVariant
                                                                                  and $projection.BillOfOperationsSequence = _BOOOpBOMItemInternalID.BillOfOperationsSequence
                                                                                  and $projection.BOOOperationInternalID   = _BOOOpBOMItemInternalID.BOOOperationInternalID
                                                                                  and $projection.BOOOpBOMItemInternalID   = _BOOOpBOMItemInternalID.BOOOpBOMItemInternalID

  association [0..*] to I_BillOfMaterialItem        as _BillOfMaterialItem        on  $projection.BillOfMaterialCategory       = _BillOfMaterialItem.BillOfMaterialCategory
                                                                                  and $projection.BillOfMaterial               = _BillOfMaterialItem.BillOfMaterial
                                                                                  and $projection.BillOfMaterialVariant        = _BillOfMaterialItem.BillOfMaterialVariant
                                                                                  and $projection.BillOfMaterialItemNodeNumber = _BillOfMaterialItem.BillOfMaterialItemNodeNumber
  association [0..1] to I_ChangeMaster              as _ChangeMaster              on  $projection.ChangeNumber = _ChangeMaster.ChangeNumber
  -- for ESH
  association [0..1] to I_BillOfMaterialItemBasic   as _BillOfMaterialItemBasic   on $projection.BillOfMaterialCategory = _BillOfMaterialItemBasic.BillOfMaterialCategory
                                                                                  and $projection.BillOfMaterial = _BillOfMaterialItemBasic.BillOfMaterial
                                                                                  and $projection.BillOfMaterialItemNodeNumber = _BillOfMaterialItemBasic.InheritedNodeNumberForBOMItem
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plnty                                                          as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key plnnr                                                          as   BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plnal                                                          as   BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plnfl                                                          as   BillOfOperationsSequence,

      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key plnkn                                                          as   BOOOperationInternalID,

      @ObjectModel.foreignKey.association: '_BOOOpBOMItemInternalID'
  key zuonr                                                          as   BOOOpBOMItemInternalID,

  key zaehl                                                          as   BOOOpBOMItemIntVersCounter,

      versn                                                          as   BillOfOperationsVersion,

      @Semantics.businessDate.from: true
      datuv                                                          as   ValidityStartDate,
      @Semantics.businessDate.to: true
      valid_to                                                       as   ValidityEndDate,

      --- Administration Data ---
      @Semantics.systemDate.createdAt: true
      andat                                                          as   CreationDate,
      cast(annam as vdm_createdbyuserid preserving type)             as   CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                                          as   LastChangeDate,
      cast(aenam as vdm_lastchangedbyuserid preserving type)         as   LastChangedByUser,

      loekz                                                          as   IsDeleted,
      loekz_inherited                                                as   IsImplicitlyDeleted,

      @ObjectModel.foreignKey.association: '_ChangeMaster'
      aennr                                                          as   ChangeNumber,
      @Semantics.text: true
      cast(wempf as pph_wempf  preserving type)                      as   GoodsRecipientName,
      @Semantics.text: true
      cast(ablad as ablad      preserving type)                      as   UnloadingPointName,

      --- Assigned Component ---
      stlty                                                          as   BillOfMaterialCategory,
      stlnr                                                          as   BillOfMaterial,
      stlal                                                          as   BillOfMaterialVariant,
      stlkn                                                          as   BillOfMaterialItemNodeNumber,

      stlty_w                                                        as   BillOfMaterialRootCategory,
      stlnr_w                                                        as   BillOfMaterialRoot,
      stlal_w                                                        as   BillOfMaterialRootVariant,
      kante                                                          as   BillOfMaterialEdgeNumber,

      rgekz                                                          as   MatlCompIsMarkedForBackflush,

      --- QM ---
      disp                                                           as   ResvnIsMRPRlvtOrPurReqnIsCrted,
      // The fields IMENG and IMEIN in PLMZ are only maintained for a few task list types, e.g. 'A' and 'E'. They are NOT maintained in PLMZ for task list types 'N' and 'V'!

      @Semantics.quantity.unitOfMeasure: 'BILLOFMATERIALITEMUNIT' 
imeng                                                          as   BillOfMaterialItemQuantity,
      imein                                                          as   BillOfMaterialItemUnit,

      --- Associations
      _BillOfMaterialItem,
      _BillOfOperations,
      // !! DO NOT USE @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]

      _BillOfOperationsGroup,
      // !! DO NOT USE @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]

      _BillOfOperationsOperation,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BOOOpBOMItemInternalID,
      _BOOOperationInternalID,
      _ChangeMaster,
      _BillOfMaterialItemBasic
}