I_RetsMgmtProcgStatusText

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'RetsMgmtProcessingStatus'
@ObjectModel.usageType.dataClass:  #META 
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'Returns Management Processing Status Text'
@Analytics.dataExtraction.enabled: false
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:  #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'IRMRTSPROCGSTST'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@Search.searchable: true
define view I_RetsMgmtProcgStatusText

as select from
dd07t

association[0..1] to I_RetsMgmtProcgStatus
as _RetsMgmtProcessingStatus 
on $projection.RetsMgmtProcessingStatus = _RetsMgmtProcessingStatus.RetsMgmtProcessingStatus

association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{

    //Key

    @ObjectModel.foreignKey.association: '_RetsMgmtProcessingStatus'
    key substring(domvalue_l, 1, 1) as RetsMgmtProcessingStatus,
    
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'
    key ddlanguage as Language,
    
    //Description

    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #LOW
    ddtext as RetsMgmtProcessingStatusDesc,
    
    //Associations

    _RetsMgmtProcessingStatus,
    _Language
}
where (dd07t.domname = 'MSR_PROC_STATUS') and (dd07t.as4local = 'A');