I_RetailPromotionDiscount

@Analytics.technicalName: 'IRTLPROMNDISC'
@EndUserText.label: 'Retail Promotion Discount'
@AccessControl.authorizationCheck: #CHECK
@VDM: {viewType: #BASIC}

@ObjectModel: {
    semanticKey: ['RetailPromotion', 'RetailPromotionDiscount'],
    representativeKey: 'RetailPromotionDiscount',
    usageType: {
        serviceQuality: #A,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
   }
}
define view entity I_RetailPromotionDiscount
  as select from wakr

  association [1..1] to I_RetailPromotion        as _RetailPromotion           on  $projection.RetailPromotion = _RetailPromotion.RetailPromotion
  association [1..1] to I_RtlPromnDiscountLevel  as _RtlPromnDiscountLevel     on  $projection.RetailPromnDiscountLevel = _RtlPromnDiscountLevel.RetailPromnDiscountLevel
  association [1..1] to I_RtlPromnDiscountStatus as _RtlPromnDiscountStatus    on  $projection.RetailPromotionDiscountStatus = _RtlPromnDiscountStatus.RetailPromotionDiscountStatus
  association [0..1] to I_ClassHeader            as _ProductGroup              on  $projection.ProductGroup = _ProductGroup.Class
                                                                               and _ProductGroup.ClassType  = '026' // is unique with Retail Class Type

  association [0..1] to I_ArticleHierProperties  as _ArticleHierProperties     on  $projection.RetailArticleHierarchy = _ArticleHierProperties.HierarchyID
  association [0..*] to I_CategoryStruc          as _ArticleHierNodeProperties on  $projection.RetailArticleHierarchy     = _ArticleHierNodeProperties.HierarchyID
                                                                               and $projection.RetailArticleHierarchyNode = _ArticleHierNodeProperties.HierarchyNode
  association [0..1] to I_Currency               as _Currency                  on  $projection.RetailPromnDiscountCurrency = _Currency.Currency
  association [0..1] to I_UnitOfMeasure          as _QuantityUnit              on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure
{

      @ObjectModel: {foreignKey: {association: '_RetailPromotion'}}
  key aktnr                as RetailPromotion,

  key posnr                as RetailPromotionDiscount,

      @ObjectModel: {foreignKey: {association: '_RtlPromnDiscountLevel'}}
      reb_level            as RetailPromnDiscountLevel,

      @ObjectModel: {foreignKey: {association: '_ProductGroup'}}
      case reb_level
        when '02' then matkl       // Product Group (former Material Group)

        when '03' then wghier      // Product Group Hierarchy Node which is also a Product Group

                  else ''
      end                  as ProductGroup, //ACH: cast to ClassNumber which is DTEL KLASSE_D, but not 1 day before vacation may effect factsheet

      _ProductGroup,


      @ObjectModel: {foreignKey: {association: '_Currency'}}
      reb_curr             as RetailPromnDiscountCurrency,
      _Currency,

      @Semantics.amount.currencyCode: 'RetailPromnDiscountCurrency'
      reb_value            as RetailPromnDiscountAmount,
      _RtlPromnDiscountLevel,

      cast( '%' as mebme ) as QuantityUnit,
      _QuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      reb_perc             as RetailPromotionDiscountPercent,

      @ObjectModel: {foreignKey: {association: '_RtlPromnDiscountStatus'}}
      reb_status           as RetailPromotionDiscountStatus,
      _RtlPromnDiscountStatus,

      reb_unit             as RetailPromnDiscountUnit,

      @ObjectModel: {foreignKey: {association: '_ArticleHierProperties'}}
      hier_id              as RetailArticleHierarchy,
      _ArticleHierProperties,

      node                 as RetailArticleHierarchyNode,
      _ArticleHierNodeProperties,

      saiso                as MaterialSeasonCategory,

      saisj                as MaterialSeasonYear,



      // Make association public



      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _RetailPromotion
}