I_RequestForQuotationItem

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{ representativeKey: 'RequestForQuotationItem',
               semanticKey: 'RequestForQuotationItem',
               usageType.dataClass:  #TRANSACTIONAL,
               usageType.serviceQuality: #A,
               usageType.sizeCategory: #L }           
@EndUserText.label: 'Request For Quotation Item'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'IMMRFQITEM'

define view I_RequestForQuotationItem  
  as select from R_PurchasingDocumentItem
 
  association [1..1] to I_RequestForQuotation         as _RequestForQuotation         on  $projection.RequestForQuotation = _RequestForQuotation.RequestForQuotation

  association [0..1] to I_PurchasingDocumentCategory  as _PurchasingDocumentCategory  on  $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory

  association [0..1] to I_IncotermsClassification     as _IncotermsClassification     on  $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification

  association [0..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant

  association [0..1] to I_UnitOfMeasure               as _OrderQuantityUnit           on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure

  association [0..*] to I_SupplierQuotationItem       as _SupplierQuotationItem       on  $projection.RequestForQuotation     = _SupplierQuotationItem.RequestForQuotation
                                                                                      and $projection.RequestForQuotationItem = _SupplierQuotationItem.RequestForQuotationItem
{
      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_RequestForQuotation' }
  key R_PurchasingDocumentItem.PurchasingDocument                                           as RequestForQuotation,

      @ObjectModel: { readOnly: true }
  key cast (R_PurchasingDocumentItem.PurchasingDocumentItem as vdm_requestforquotationitem preserving type) as RequestForQuotationItem,

      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_PurchasingDocumentCategory' }
      R_PurchasingDocumentItem.PurchasingDocumentCategory,

      R_PurchasingDocumentItem.PurchasingDocumentItemText,

      R_PurchasingDocumentItem.Material,
      
      @ObjectModel.foreignKey.association: '_ProductType'
      ProductType,

      cast (R_PurchasingDocumentItem.ManufacturerMaterial as vdm_manufacturer_material preserving type) as ManufacturerMaterial,

      R_PurchasingDocumentItem.ManufacturerPartNmbr,
      R_PurchasingDocumentItem.Manufacturer,

      R_PurchasingDocumentItem.MaterialGroup,

      @ObjectModel: { foreignKey.association: '_Plant' }
      R_PurchasingDocumentItem.Plant,

      R_PurchasingDocumentItem.ManualDeliveryAddressID,
      R_PurchasingDocumentItem.ReferenceDeliveryAddressID,

      @ObjectModel: { foreignKey.association: '_IncotermsClassification' }
      R_PurchasingDocumentItem.IncotermsClassification,

      R_PurchasingDocumentItem.IncotermsTransferLocation,

      R_PurchasingDocumentItem.IncotermsLocation1,
      R_PurchasingDocumentItem.IncotermsLocation2,

      @Semantics.unitOfMeasure: true
      @ObjectModel: { foreignKey.association: '_OrderQuantityUnit' }
      R_PurchasingDocumentItem.OrderQuantityUnit,

      R_PurchasingDocumentItem.OrderItemQtyToBaseQtyNmrtr,
      R_PurchasingDocumentItem.OrderItemQtyToBaseQtyDnmntr,

      @Semantics.unitOfMeasure: true
      R_PurchasingDocumentItem.BaseUnit,

      R_PurchasingDocumentItem.PurchaseRequisition,
      R_PurchasingDocumentItem.PurchaseRequisitionItem,
      
      R_PurchasingDocumentItem.PurchasingInfoRecordUpdateCode as IsInfoRecordUpdated,
      
      R_PurchasingDocumentItem.RequirementTracking,
      
      @ObjectModel: { readOnly: true }
      R_PurchasingDocumentItem.PurchasingDocumentItemCategory,
      
      // fields for hier (2211)

      @Feature: 'SW:MM_PUR_S4SOURCNG_SFWS_ITM_HIER'
      R_PurchasingDocumentItem.PurchasingParentItem,
      @Feature: 'SW:MM_PUR_S4SOURCNG_SFWS_ITM_HIER'
      R_PurchasingDocumentItem.PurgDocAggrgdSubitemCategory,
      @Feature: 'SW:MM_PUR_S4SOURCNG_SFWS_ITM_HIER'
      R_PurchasingDocumentItem.IsStatisticalItem,
      @Feature: 'SW:MM_PUR_S4SOURCNG_SFWS_ITM_HIER'
      R_PurchasingDocumentItem.PurgExternalSortNumber,
      @Feature: 'SW:MM_PUR_S4SOURCNG_SFWS_ITM_HIER'
      R_PurchasingDocumentItem.PurgConfigurableItemNumber,

      /*Associations*/
      _RequestForQuotation,
      _IncotermsClassification,
      _PurchasingDocumentCategory,
      _Material,
      _ManufacturerMaterial,
       R_PurchasingDocumentItem._ProductType,
      _Manufacturer,
      _MaterialGroup,
      _Plant,
      _ManualDeliveryAddress,
      _ReferenceDeliveryAddress,
      _BaseUnit,
      _OrderQuantityUnit,
      _SupplierQuotationItem,
      _PurgDocumentItemCategory

}
where
  R_PurchasingDocumentItem.PurchasingDocumentCategory = 'R'