I_RSHProjectAssignmentTP

@AbapCatalog.sqlViewName: 'IRSHPROJASGTP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Project Assignment TP'
@Metadata.allowExtensions: true
@Search.searchable: false
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    transactionalProcessingEnabled: true,
    writeActivePersistence: 'RSH_D_PROJASG',
    writeDraftPersistence: 'RSH_D_PROJASG_D',

    lifecycle.enqueue.expiryBehavior: #RELATIVE_TO_LAST_CHANGE,
    lifecycle.enqueue.expiryInterval: 'PT1M', //Lock shall expire between 1 to 5 minutes! The draft lifecycle handler runs every 5 minutes!

    lifecycle.processing.expiryBehavior: #RELATIVE_TO_LAST_CHANGE,
    lifecycle.processing.expiryInterval: 'PT1M', //Draft shall expire between 1 to 5 minutes too!


    lifecycle.draft.expiryInterval: 'P1D', // Any unused draft shall be deleted after 1 day!


    entityChangeStateId: 'ProjAssignmentLastChangedAt',
    draftEnabled: true,
    compositionRoot: true,
    createEnabled: true, updateEnabled: true, deleteEnabled: true,
    semanticKey: 'ProjAssignmentUUID',
    usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #D, sizeCategory: #XL }
    }

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

/*
CONTRACT**********************************************************************************************************************

Name:                       Assignment transaction processing
Specification:              The view creates the draft enabled BO.
Requires:                   NA
Ensures:                    The draft enabled business object is created.
Owners:                     PSP
Contributors:               CF, PSP, RY
Unit Test required Y/N:     Y
Additional comments         None

END OF CONTRACT***************************************************************************************************************
*/

define view I_RSHProjectAssignmentTP
  as select from I_RSHProjectAssignment

  association [0..*] to I_RSHProjectAssignmentPerDayTP as _ProjectAssignmentPerDay   on _ProjectAssignmentPerDay.ProjAssignmentUUID = $projection.ProjAssignmentUUID

  association [0..*] to I_RSHProjectAssignmentKPITP    as _ProjectAssignmentKPI      on _ProjectAssignmentKPI.ProjAssignmentUUID = $projection.ProjAssignmentUUID

  association [0..*] to I_RSHProjectAssignmentCapKPITP as _ProjectAssignmentCapKPI   on _ProjectAssignmentCapKPI.ProjAssignmentUUID = $projection.ProjAssignmentUUID

  association [0..*] to I_RSHProjectAssgmtPerWeekTP as _ProjectAssignmentPerWeek  on _ProjectAssignmentPerWeek.ProjAssignmentUUID = $projection.ProjAssignmentUUID

  association [0..*] to I_RSHProjectAssgmtPerMonthTP   as _ProjectAssignmentPerMonth on _ProjectAssignmentPerMonth.ProjAssignmentUUID = $projection.ProjAssignmentUUID

{
  key ProjAssignmentUUID,
      EmploymentInternalID,
      ResourceDemandUUID,
      SourceOfSupply,
      SourceOfDraftCreationInRSH,
      
      ProjAssignmentDistributionRule,
      ProjAssignmentStartDate,
      ProjAssignmentEndDate,
      ProjAssignmentTotalHours,
      ProjAssignmentHoursPerDay,
      ProjAssignmentUtilization,
      dats_add_days(cast( concat( left(ProjAssignmentStartDate, 6 ), '01') as dats), -36, 'FAIL')  as ProjAssignDayCapacityStartDate,
      dats_add_days(cast( concat( left(ProjAssignmentStartDate, 6 ), '01') as dats), 67, 'FAIL')   as ProjAssignDayCapacityEndDate,
      ProjAssignIsDistrToSpecifDays,
      ProjAssignIsDistrToMonday,
      ProjAssignIsDistrToTuesday,
      ProjAssignIsDistrToWednesday,
      ProjAssignIsDistrToThursday,
      ProjAssignIsDistrToFriday,
      ProjAssignIsDistrToSaturday,
      ProjAssignIsDistrToSunday,
      @Semantics.user.createdBy: true
      ProjAssignmentCreatedBy,
      @Semantics.systemDateTime.createdAt: true
      ProjAssignmentCreatedAt,
      @Semantics.user.lastChangedBy: true
      ProjAssignmentLastChangedBy,
      @Semantics.systemDateTime.lastChangedAt: true
      ProjAssignmentLastChangedAt,
      ProjAssignmentLifeCycle,
      //Passback the field to be used in the assignemnt structure

      EmployeeRequestOpenDuration,
      ProjectLastChangedDateTime,

      cast( EmployeeUtilLvlOverbooked as rsh_ps_overbooked_threshold )                             as EmployeeUtilLvlOverbooked,
      cast( EmployeeUtilLvlFreeCapacity as rsh_ps_free_capacity_threshold )                        as EmployeeUtilLvlFreeCapacity,


      /* Associations */
      //_Employment,

      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _ProjectAssignmentPerDay,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _ProjectAssignmentKPI,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _ProjectAssignmentCapKPI,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _ProjectAssignmentPerWeek,
      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _ProjectAssignmentPerMonth
}