I_RO_SAFTMatlDocLineItem

@VDM.viewType: #COMPOSITE
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'RO SAFT Matl Doc Lines'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@Analytics.internalName:#LOCAL
@Analytics: { dataCategory: #CUBE }
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@Consumption.dbHints: ['PREAGGR_BEFORE_JOIN']
define view entity I_RO_SAFTMatlDocLineItem
  as select from I_MaterialDocumentRecord   as _Matdoc

  inner join I_RO_SAFTDocumentTypeMap       as _DocumentMap
                                                          on  _DocumentMap.CompanyCode = _Matdoc.CompanyCode
                                                          and _DocumentMap.AccountingDocumentType = _Matdoc.AccountingDocumentType
                                                          and _DocumentMap.RO_SAFTSourceDocumentType = '05'
  inner join t001w                                        as  _Plant
                                                          on  _Matdoc.Plant = _Plant.werks
  association [0..1] to I_CompanyCode                     as  _CompanyCode
                                                          on  _CompanyCode.CompanyCode = _Matdoc.CompanyCode
  association [0..1] to t001k                             as  _ValuationArea
                                                          on  _Plant.bwkey = _ValuationArea.bwkey
  association [0..1] to I_RO_SAFTProductValuation         as  _Valuation
                                                          on  _Matdoc.StockIdentifyingMaterial = _Valuation.Product
                                                          and _Plant.bwkey = _Valuation.ValuationArea
                                                          and _Matdoc.InventoryValuationType = _Valuation.ValuationType
  association [0..1] to I_ProductUnitsOfMeasure
                                            as _ProductUom
                                                          on  _Matdoc.Material  = _ProductUom.Product
                                                          and _Matdoc.MaterialBaseUnit = _ProductUom.AlternativeUnit
  association [0..1] to I_RO_SAFTUnitOfMeasureMap
                                            as _Uom       on  _Matdoc.MaterialBaseUnit = _Uom.SourceUnitOfMeasure
  association [0..*] to I_RO_BusinessPartnerTaxType
                                            as _DCustomer on  _DCustomer.BusinessPartner = _Matdoc.Customer
                                                          and _DCustomer.BusinessPartnerIsSAFTRelevant = 'X'
                                                          and _DCustomer.TaxType = '6'
                                                          and _DCustomer.FinancialAccountType = 'D'
                                                          and _DCustomer.ValidFrom <= $session.system_date
                                                          and _DCustomer.ValidTo >=  $session.system_date
                                                          and _DCustomer.VATRegistration is not initial
  association [0..*] to I_RO_BusinessPartnerTaxType
                                            as _KSupplier on  _KSupplier.BusinessPartner = _Matdoc.Supplier
                                                          and _KSupplier.BusinessPartnerIsSAFTRelevant = 'X'
                                                          and _KSupplier.TaxType = '6'
                                                          and _KSupplier.FinancialAccountType = 'K'
                                                          and _KSupplier.ValidFrom <= $session.system_date
                                                          and _KSupplier.ValidTo >=  $session.system_date
                                                          and _KSupplier.VATRegistration is not initial
  association [0..1] to I_RO_SAFTMvtTypeTableEntry
                                            as _MovementType1
                                                          on  _MovementType1.GoodsMovementType = _Matdoc.GoodsMovementType
                                                          and _MovementType1.Plant = _Matdoc.Plant
                                                          and _MovementType1.TargetGLAccount = ''
                                                          and _MovementType1.AccountingDocumentType = _Matdoc.AccountingDocumentType
                                                          and _MovementType1.DebitCreditCode = _Matdoc.DebitCreditCode
  association [0..1] to I_RO_SAFTMvtTypeTableEntry
                                            as _MovementType2
                                                          on  _MovementType2.GoodsMovementType = _Matdoc.GoodsMovementType
                                                          and _MovementType2.Plant = _Matdoc.Plant
                                                          and _MovementType2.TargetGLAccount = ''
                                                          and _MovementType2.AccountingDocumentType = _Matdoc.AccountingDocumentType
                                                          and _MovementType2.DebitCreditCode = ''
  association [0..1] to I_RO_SAFTMvtTypeTableEntry
                                            as _MovementType3
                                                          on  _MovementType3.GoodsMovementType = _Matdoc.GoodsMovementType
                                                          and _MovementType3.Plant = _Matdoc.Plant
                                                          and _MovementType3.TargetGLAccount = ''
                                                          and _MovementType3.AccountingDocumentType = ''
                                                          and _MovementType3.DebitCreditCode = ''
  association [0..1] to I_RO_SAFTMvtTypeTableEntry
                                            as _MovementType4
                                                          on  _MovementType4.GoodsMovementType = _Matdoc.GoodsMovementType
                                                          and _MovementType4.Plant = _Matdoc.Plant
                                                          and _MovementType4.TargetGLAccount = ''
                                                          and _MovementType4.AccountingDocumentType = ''
                                                          and _MovementType4.DebitCreditCode = _Matdoc.DebitCreditCode
  association [0..1] to I_RO_SAFTMvtTypeTableEntry
                                            as _MovementType5
                                                          on  _MovementType5.GoodsMovementType = _Matdoc.GoodsMovementType
                                                          and _MovementType5.Plant = ''
                                                          and _MovementType5.TargetGLAccount = ''
                                                          and _MovementType5.AccountingDocumentType = ''
                                                          and _MovementType5.DebitCreditCode = ''
{
  key _Matdoc.MaterialDocument,
  key _Matdoc.MaterialDocumentYear,
  key _Matdoc.MaterialDocumentItem,
  key _Matdoc.CompanyCode,
      concat(
        concat( _Matdoc.CompanyCode, _Matdoc.MaterialDocumentYear ),
        concat( _Matdoc.AccountingDocumentType, _Matdoc.MaterialDocument ) ) as
       BusinessTransactionTypeName,
      _Matdoc.Material as Product,
      _Matdoc.Plant,
      _Matdoc.DebitCreditCode,
      _Matdoc.AccountingDocumentType,
      _Matdoc.MaterialBaseUnit,
      @Semantics: { quantity : {unitOfMeasure: 'MaterialBaseUnit'} }
      cast( _Matdoc.MatlStkChangeQtyInBaseUnit as menge_d ) as MatlStkChangeQtyInBaseUnit,
      _Matdoc.PostingDate,
      _Matdoc.DocumentDate,
      _Matdoc.CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Matdoc.GoodsMovementStkAmtInCCCrcy,
      _Matdoc.CreatedByUser as CreatedByUser,

      cast(
        case
          when _Matdoc.InventorySpecialStockType <> 'K'
            then concat( '00', substring(_CompanyCode.VATRegistration, 3, 20) )
          else
            ( case
                when _DCustomer.VATRegistration is not null
                  then _DCustomer.VATRegistration
                when _DCustomer.VATRegistration is null and _KSupplier.VATRegistration is null
                  then concat( '00', substring(_CompanyCode.VATRegistration, 3, 20) )
                else
                  '0' end )
        end as stceg ) as CustomerVATRegistration,

      cast(
        case
          when _Matdoc.InventorySpecialStockType <> 'K'
            then concat( '00', substring(_CompanyCode.VATRegistration, 3, 20) )
          else
            ( case
                when _KSupplier.VATRegistration is not null
                  then _KSupplier.VATRegistration
                when _KSupplier.VATRegistration is null and _DCustomer.VATRegistration is null
                  then concat( '00', substring(_CompanyCode.VATRegistration, 3, 20) )
                else
                '0' end )
        end as stceg ) as SupplierVATRegistration,

      _Matdoc.GoodsMovementType,
      _Matdoc.Batch,
      _Matdoc.MaterialDocumentItemText,
      _Uom.SourceUnitOfMeasureFactor,

      cast( case
        when _ProductUom.QuantityDenominator is not null
          then _ProductUom.QuantityNumerator / _ProductUom.QuantityDenominator
        else 0
      end as dec_23_3 ) as ConversionFactor,

      case
        when _MovementType1.RO_SAFTMovementType is not initial
          then _MovementType1.RO_SAFTMovementType
        when _MovementType2.RO_SAFTMovementType is not initial
          then _MovementType2.RO_SAFTMovementType
        when _MovementType3.RO_SAFTMovementType is not initial
          then _MovementType3.RO_SAFTMovementType
        when _MovementType4.RO_SAFTMovementType is not initial
          then _MovementType4.RO_SAFTMovementType
        else _MovementType5.RO_SAFTMovementType
      end as RO_SAFTMovementType,

      _ValuationArea.bwmod as ValuationGroupingCode,
      _Valuation.ValuationClass as ValuationClass

} where _Matdoc.MaterialDocumentRecordType = 'MDOC'
  and   _Matdoc.StockIdentifyingMaterial is not initial
  //and   _Matdoc.GoodsMovementStkAmtInCCCrcy is not initial