I_REOutputRequestBasic

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@ObjectModel.usageType: {
      serviceQuality: #B,
      sizeCategory : #L,
      dataClass: #TRANSACTIONAL }
@ObjectModel.representativeKey: 'OutputRequestUUID'
@EndUserText.label: 'Real Estate Output Requests Basic'
define view entity I_REOutputRequestBasic
  as select from R_OutputRequest //R_OutputRequestTP

                                                                
{
  key OutputRequestUUID,
      OutputControlApplObjectType,
      OutputControlApplicationObject,
      // Keys for Adjustments

      cast (case
      when OutputControlApplObjectType <> 'RE_CONTRACT_A520'
      then  substring(OutputControlApplicationObject,1,16)
      else ' '
      end as recavdmprocessid preserving type ) as RealEstateProcess,

      cast( case
      when OutputControlApplObjectType <> 'RE_CONTRACT_A520'
      then  substring(OutputControlApplicationObject,17,13)
            else ' '
      end as recnnumber preserving type ) as RealEstateContract,

      //Keys for fetching invoice data

      cast( case
        when OutputControlApplObjectType <> 'RE_CONTRACT_A520'
        then cast( substring(OutputControlApplicationObject,30,4) as abap.char(4))
        else cast( substring ( OutputControlApplicationObject, 1, 4 ) as abap.char(4))
      end as bukrs preserving type )as CompanyCode,

      cast( case
        when OutputControlApplObjectType = 'RE_CONTRACT_A520'
        then substring ( OutputControlApplicationObject, 5, 10 )
        else ' '
      end as rerainvno ) as REInvoiceNumber,

      cast (case
      when OutputControlApplObjectType = 'RE_CONTRACT_A520'
      then cast ( substring ( OutputControlApplicationObject, 15, 4 ) as abap.numc( 4 ) )
      else cast ( ' ' as abap.numc( 4 ) )
      end as gjahr preserving type ) as FiscalYear,


      OutputParameterText,
      CreationDateTime,
      CreatedByUser,
      LastChangeDateTime,
      LastChangedByUser

      /* Associations */
      //      _OutputRequestItem,

  //    _ApplObjectType

}
where
     OutputControlApplObjectType = 'RE_ADJUSTMENT'
  or OutputControlApplObjectType = 'RE_CONTRACT_A520';