I_REKeyAssgmt

@AbapCatalog.sqlViewName: 'IREKEYASS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Key Assgmt'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.semanticKey: [ 'InternalRealEstateNumber' ]

define view I_REKeyAssgmt
  as select from vicaintreno as _REKeyAssgmt

  association [1..1] to I_REObjectType as _REObjectType on $projection.RealEstateObjectType = _REObjectType.RealEstateObjectType
  association [1..1] to I_CompanyCode  as _CompanyCode  on $projection.CompanyCode = _CompanyCode.CompanyCode

{
  key       intreno                                      as InternalRealEstateNumber,
            @ObjectModel.foreignKey.association: '_REObjectType'
            objtype                                      as RealEstateObjectType,
            identkey                                     as REIdentificationKey,
            objnr                                        as REStatusObject,
            cast(imkey as recaimkeyfi preserving type )  as REInternalFinNumber,
            @ObjectModel.foreignKey.association: '_CompanyCode'
            bukrs                                        as CompanyCode,
            cast(recnnr as recnvdmcnnr preserving type ) as RealEstateContract, 
            cast(swenr as rebdvdmbeno  preserving type ) as REBusinessEntity,
            cast(smenr as rebdvdmrono preserving type )  as RERentalObject,
            cast(sgenr as rebdvdmbuno preserving type )  as RealEstateBuilding,
            cast(sgrnr as rebdvdmprno preserving type )  as RealEstateProperty,
            aoid                                         as ArchitecturalObject,
            //PGID

            cast(snksl as rescvdmsckey preserving type ) as REServiceChargeKey,
            cast(sempsl as rescvdmsuid preserving type ) as RESettlementUnitID,
            //COMPGRP

            _REObjectType,
            _CompanyCode

}