I_RDPSlsDocCompletePartner

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.status: #DEPRECATED,
  lifecycle.successor: 'P_SustSlsDocCompletePartner'
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: [ '_Address' ]
}
@AbapCatalog: {
  sqlViewName: 'RDPSLSDOCCOMPPAR',
  compiler.compareFilter: true,
  dataMaintenance: #DISPLAY_ONLY
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   }
}

define view I_RDPSlsDocCompletePartner // copy of I_SDDocumentCompletePartners to fix delta handling issue described in SAP note 3244770

  as

  select from vbpa

  association [0..1] to I_PartnerFunction        as _PartnerFunction               on  $projection.PartnerFunction = _PartnerFunction.PartnerFunction
  association [0..1] to I_ContactPerson          as _ContactPerson                 on  $projection.ContactPerson = _ContactPerson.ContactPerson

  association [0..1] to I_Address_2              as _Address                       on  $projection.AddressID = _Address.AddressID
                                                                                   and $projection.AddressPersonID = _Address.AddressPersonID
                                                                                   and _Address.AddressRepresentationCode is initial

  association [0..1] to I_BusPartAddress         as _BusinessPartnerAddress        on  $projection.ReferenceBusinessPartner   = _BusinessPartnerAddress.BusinessPartner
                                                                                   and $projection.AddressID                  = _BusinessPartnerAddress.AddressID
                                                                                   and $projection.SDDocPartnerAddressRefType = 'H'
{
  key vbpa.vbeln          as SDDocument,
  key vbpa.posnr          as SDDocumentItem,
  @ObjectModel.foreignKey.association: '_PartnerFunction'
  key cast(vbpa.parvw as parvw_unv) as PartnerFunction,

      vbpa.kunnr          as Customer,
      vbpa.lifnr          as Supplier,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      vbpa.parnr          as ContactPerson,
      vbpa.assigned_bp    as ReferenceBusinessPartner,

      // Address related fields

      @ObjectModel.foreignKey.association: '_Address'
      vbpa.adrnr          as AddressID,
      vbpa.adrnp          as AddressPersonID,      
      vbpa.adrda          as SDDocPartnerAddressRefType,

      _PartnerFunction,
      _ContactPerson,

      // Address related associations

      _Address,
      _BusinessPartnerAddress

};