I_QltyNotifActivityLongText

DDL: I_QLTYNOTIFACTIVITYLONGTEXT SQL: IQTNOTIFACTLT Type: view BASIC

Quality Notification Activity Long Text

I_QltyNotifActivityLongText is a Basic CDS View that provides data about "Quality Notification Activity Long Text" in SAP S/4HANA. It reads from 1 data source (qmmaltext) and exposes 14 fields with key fields QualityNotification, NotificationActivity, Language, ItemCounter. It has 3 associations to related views.

1 data source(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
qmmaltext qmmaltext from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_QltyNotification _QltyNotification $projection.QualityNotification = _QltyNotification.QualityNotification
[1..1] I_QltyNotificationActivity _QltyNotificationActivity $projection.QualityNotification = _QltyNotificationActivity.QualityNotification and $projection.NotificationActivity = _QltyNotificationActivity.NotificationActivity
[1..1] I_Language _Language $projection.Language = _Language.Language

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName IQTNOTIFACTLT view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #CHECK view
ObjectModel.dataCategory #TEXT view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.representativeKey NotificationActivity view
EndUserText.label Quality Notification Activity Long Text view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY QualityNotification qmnum
KEY NotificationActivity manum
KEY Language langu
KEY ItemCounter counter
LongTextID textid
QltyNotifActivityLongText content
LongTextCreatedByUser created_by
LongTextCreatedAt created_at
LongTextLastChangedByUser changed_by
LongTextLastChangedAt changed_at
MimeType mimetype
_QltyNotification _QltyNotification
_QltyNotificationActivity _QltyNotificationActivity
_Language _Language 
@AbapCatalog.sqlViewName: 'IQTNOTIFACTLT'

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
    dataCategory: #TEXT,
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C
    },
    representativeKey: 'NotificationActivity'
}
@EndUserText.label: 'Quality Notification Activity Long Text'
define view I_QltyNotifActivityLongText as select from qmmaltext
    
    association [1..1] to I_QltyNotification            as _QltyNotification        on $projection.QualityNotification = _QltyNotification.QualityNotification  
    association [1..1] to I_QltyNotificationActivity    as _QltyNotificationActivity    on  $projection.QualityNotification     = _QltyNotificationActivity.QualityNotification and
                                                                                            $projection.NotificationActivity    = _QltyNotificationActivity.NotificationActivity
    association [1..1] to I_Language                as _Language            on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_QltyNotification'
    key qmnum                                                       as QualityNotification,
    
    @ObjectModel.foreignKey.association: '_QltyNotificationActivity'
    key manum                                                       as NotificationActivity,   
    
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key langu                                                       as Language,
    
    key counter                                                     as ItemCounter,
    
    textid                                                          as LongTextID,
    
    @Semantics.text
    content     as QltyNotifActivityLongText,
    
    created_by  as LongTextCreatedByUser,
    created_at  as LongTextCreatedAt,
    changed_by  as LongTextLastChangedByUser,
    changed_at  as LongTextLastChangedAt,
    mimetype    as MimeType,
    
    /* Association */
    _QltyNotification,
    _QltyNotificationActivity,
    _Language    
} where qmmaltext.qmnum not like '$%'
        and qmmaltext.textid = 'LTQM' --ensures that only items of quality notifications are selected

Learn More