I_PurOrdAcctAssignmentTP

@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'IPOACCTASSTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transactional View for PO Account Assignment'

@ObjectModel: {
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem', 'AccountAssignmentNumber'],
    representativeKey: 'AccountAssignmentNumber',
    createEnabled: 'EXTERNAL_CALCULATION',
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'POACCTASSTP_D' 
}

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view I_PurOrdAcctAssignmentTP
  as select from I_PurOrdAccountAssignment as Document


  association [1..1] to I_PurchaseOrderTP           as _PurchaseOrderTP     on  _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
  association [1..1] to I_PurchaseOrderItemTP       as _PurchaseOrderItemTP on  _PurchaseOrderItemTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                            and _PurchaseOrderItemTP.PurchaseOrderItem = $projection.PurchaseOrderItem
                                                                    
  association [0..1] to I_WBSElementByInternalKey   as _WBSElementByInternalKey   on  _WBSElementByInternalKey.WBSElementInternalID = $projection.WBSElementInternalID                                                                    

  //association [0..1] to I_WBSElementBasicData       as _WBSElement                on  _WBSElement.WBSElementInternalID = $projection.WBSElementInternalID

  
  association [0..1] to I_CostCenter                as _CostCenter                on  _CostCenter.ControllingArea = $projection.ControllingArea
                                                                                  and _CostCenter.CostCenter = $projection.CostCenter
                                                                                  and _CostCenter.CompanyCode = $projection.CompanyCode
                                                                                  and _CostCenter.ValidityEndDate >= $projection.ValidityDate
                                                                                  and _CostCenter.ValidityStartDate <= $projection.ValidityDate
  association [0..1] to I_GLAccount                 as _GLAccount                 on  $projection.GLAccount   = _GLAccount.GLAccount
                                                                                  and $projection.CompanyCode = _GLAccount.CompanyCode                                                                               
                                                                                
  association[0..1] to I_CompanyCode                as _CompanyCode               on $projection.CompanyCode = _CompanyCode.CompanyCode 
  
  association[0..1] to I_FundedPgmByAcctAssgmtNmbr  as _FundedProgram             on  $projection.PurchaseOrder           = _FundedProgram.PurchasingDocument
                                                                                  and $projection.PurchaseOrderItem       = _FundedProgram.PurchasingDocumentItem
                                                                                  and $projection.AccountAssignmentNumber = _FundedProgram.AccountAssignmentNumber

{

      @ObjectModel.foreignKey.association: '_PurchaseOrderTP'
  key Document.PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItemTP'
  key Document.PurchaseOrderItem,
  key Document.AccountAssignmentNumber,
  
      _PurchaseOrderItemTP.AccountAssignmentCategory,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
      Document.CostCenter,

      Document.MasterFixedAsset,

      Document.ProjectNetwork,
      
      cast (Document.NetworkActivity as vornr ) as  NetworkActivity,
      
      Document.OrderQuantityUnit,

      Document.Quantity,

      Document.MultipleAcctAssgmtDistrPercent,

      Document.PurgDocNetAmount,
      
      Document.DocumentCurrency,

      Document.IsDeleted,

      Document.GLAccount,

      Document.BusinessArea,

      Document.SalesOrder,

      Document.SalesOrderItem,

      Document.SalesOrderScheduleLine,

      Document.FixedAsset,

      Document.OrderID,
      
      cast( Document.OrderOperation as vornr_auf ) as OrderOperation,

      Document.UnloadingPointName,

      Document.ControllingArea,

      Document.CostObject,

      Document.ProfitabilitySegment,

      Document.ProfitCenter,

      Document.WBSElementInternalID,
      
      _WBSElement.WBSElement,
      
      _WBSElement.WBSElementExternalID,

      _WBSElement.WBSDescription,
      
      Document.ProjectNetworkInternalID,

      Document.CommitmentItem,

      Document.FundsCenter,

      Document.Fund,

      Document.FunctionalArea,

      Document.LastChangedDate,

      Document.GoodsRecipientName,

      Document.IsFinallyInvoiced,

      cast (Document.REInternalFinNumber as imkey)  as RealEstateObject,

      Document.NetworkActivityInternalID,

      Document.PartnerAccountNumber,

      Document.JointVentureRecoveryCode,

      Document.SettlementReferenceDate,

      Document.OrderInternalID,

      Document.OrderIntBillOfOperationsItem,

      Document.TaxCode,

      Document.TaxJurisdiction,

      Document.NonDeductibleInputTaxAmount,

      Document.CostCtrActivityType,

      Document.BusinessProcess,

      Document.GrantID,

      Document.BudgetPeriod,

      Document.EarmarkedFundsDocument,
      
      Document.EarmarkedFundsItem, //     deprecated, use EarmarkedFundsDocumentItem

      
      Document.EarmarkedFundsDocumentItem,
      
      cast (_FundedProgram.FundedProgram as fm_measure) as FundedProgram,

      Document.ValidityDate,

      Document.ChartOfAccounts,
      
      Document.CompanyCode,
      
      Document.ServiceDocumentType,
      
      Document.ServiceDocument,
      
      Document.ServiceDocumentItem,
      
      Document.PubSecSplitBatchNumberID,
      
      Document.PubSecSplitAuthznGroup,
      
      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      cast ('' as hghstmsgsvrtylvl)  as  HighestMessageSeverityLevel,
      
      cast (' ' as char1 ) as IsMultipleAccountAssignment, 
      
      _CompanyCode.FinancialManagementArea as FinancialManagementArea,
            
      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _PurchaseOrderTP,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _PurchaseOrderItemTP,

      _CompanyCode,

      _CostCenter,
     
      _BusinessArea,

      _ProfitCenter,

      _SalesOrderItem,

      _SalesOrder,

      _ControllingArea,

      _GLAccount,

      _SalesDocumentScheduleLine,

      _WBSElementByInternalKey,

      _FunctionalArea,

      _CostCenterActivityType,

      _BusinessProcess,

      _TaxCode,

      _TaxJurisdiction,

      _FixedAssetWorklist,

      _CostCenterText,

      _GLAccountText,

      _BusinessAreaText,

      _ProfitCenterText,

      _FunctionalAreaText,

      _CostCenterActivityTypeText,

      _BusinessProcessText,

      _TaxCodeText,

      _TaxJurisdictionText,
   
      _AcctgServiceDocumentTypeVH,
      
      _AcctgServiceDocumentVH,
       
      _AcctgServiceDocumentItemVH       
}